overlay

commit: 9600536dbe1685113488c5d41b4d7a2f33c906b5
parent: a94da09a3aa9dcf63086ea8870e7493f5b2c1a43
Author: Haelwenn (lanodan) Monnier <contact@hacktivis.me>
Date:   Fri, 18 Sep 2020 09:33:07 +0200

net-misc/streamlink: Gentoo Version Bump, 1.5.0

Diffstat:
A
net-misc/streamlink/Manifest
1
+
A
net-misc/streamlink/streamlink-1.5.0.ebuild
58
++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

2 files changed, 59 insertions(+), 0 deletions(-)
diff --git a/net-misc/streamlink/Manifest b/net-misc/streamlink/Manifest
@@ -0,0 +1 @@
+DIST streamlink-1.5.0.tar.gz 722676 BLAKE2B 89ae0e75a4fb98a8fd787613e1bb8a2ccf9de515908b0c56e063b5d185600e7ca1ff4d6c10b1a6e535db0b66e9d7f04d6bfeea36e8d5ef008082eea8edb89eec SHA512 6b54ec5d9234c1657fad711a61160ca883df409eb1e54cbe7e4a72a2eca36590ab73916ea88162f8fcf057345ae9f5e55c6591ff11088be0c2c3168ad905d458
diff --git a/net-misc/streamlink/streamlink-1.5.0.ebuild b/net-misc/streamlink/streamlink-1.5.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+PYTHON_REQ_USE='xml(+),threads(+)'
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_SETUPTOOLS=rdepend
+
+inherit distutils-r1
+
+DESCRIPTION="CLI for extracting streams from websites to a video player of your choice"
+HOMEPAGE="https://streamlink.github.io/"
+SRC_URI="https://github.com/streamlink/${PN}/releases/download/${PV}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+LICENSE="BSD-2 Apache-2.0"
+SLOT="0"
+IUSE="doc"
+
+DEPEND="
+	$(python_gen_cond_dep '
+		>dev-python/requests-2.21.0[${PYTHON_MULTI_USEDEP}]
+		dev-python/isodate[${PYTHON_MULTI_USEDEP}]
+		dev-python/websocket-client[${PYTHON_MULTI_USEDEP}]
+		dev-python/pycountry[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pycryptodome-3.4.3[${PYTHON_MULTI_USEDEP}]
+	')
+"
+RDEPEND="${DEPEND}
+	media-video/rtmpdump
+	media-video/ffmpeg
+"
+BDEPEND="
+	$(python_gen_cond_dep '
+		doc? (
+			dev-python/sphinx[${PYTHON_MULTI_USEDEP}]
+			dev-python/docutils[${PYTHON_MULTI_USEDEP}]
+			dev-python/recommonmark[${PYTHON_MULTI_USEDEP}]
+		)
+	')"
+
+python_configure_all() {
+	# Avoid iso-639, iso3166 dependencies since we use pycountry.
+	export STREAMLINK_USE_PYCOUNTRY=1
+}
+
+python_compile_all() {
+	use doc && emake -C docs html man
+}
+
+python_install_all() {
+	if use doc; then
+		local HTML_DOCS=( docs/_build/html/. )
+		doman docs/_build/man/*
+	fi
+	distutils-r1_python_install_all
+}