overlay

commit: 8cf24783bb2281bc9d48a9ac5b88871215cee086
parent: 06126fec0c75d58e7e4cb8feacc1b75daf7127c7
Author: Haelwenn (lanodan) Monnier <contact@hacktivis.me>
Date:   Thu, 10 Oct 2019 06:49:46 +0200

net-libs/glib-networking: Restore 2.62.1

Diffstat:
A
net-libs/glib-networking/glib-networking-2.62.1.ebuild
62
++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++

1 file changed, 62 insertions(+), 0 deletions(-)
diff --git a/net-libs/glib-networking/glib-networking-2.62.1.ebuild b/net-libs/glib-networking/glib-networking-2.62.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 2018-2019 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome2-utils meson xdg multilib-minimal
+
+DESCRIPTION="Network-related giomodules for glib"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/${PN}"
+SRC_URI="https://ftp.gnome.org/pub/GNOME/sources/${PN}/$(ver_cut 1-2)/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gnome gnutls +libproxy libressl +openssl test ssl"
+KEYWORDS="~amd64"
+
+REQUIRED_USE="ssl? ( || ( gnutls openssl ) )"
+
+DEPEND="
+	>=dev-libs/glib-2.60:2[${MULTILIB_USEDEP}]
+	libproxy? ( >=net-libs/libproxy-0.3.1:=[${MULTILIB_USEDEP}] )
+	gnutls? ( >=net-libs/gnutls-3.4.6:=[${MULTILIB_USEDEP}] )
+	openssl? (
+		!libressl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
+		libressl? ( dev-libs/libressl:=[${MULTILIB_USEDEP}] )
+	)
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_feature gnutls)
+		$(meson_feature openssl)
+		$(meson_feature libproxy)
+		$(meson_feature gnome gnome_proxy)
+		-Dinstalled_tests=false
+		-Dstatic_modules=false
+	)
+
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_install() {
+	meson_src_install
+}
+
+multilib_src_test() {
+	meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	multilib_foreach_abi gnome2_giomodule_cache_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	multilib_foreach_abi gnome2_giomodule_cache_update
+}