overlay

commit: 30d20514ddd9435e5508930806488cf54965c926
parent 5f665dd049c43ec5b57d7bf16e9e983ef2602f4b
Author: Ryan Qian <i@bitbili.net>
Date:   Wed, 21 Sep 2022 07:45:24 +0200

app-i18n/fcitx: import from ::ryans

Diffstat:
A
app-i18n/fcitx/Manifest
2
++
A
app-i18n/fcitx/fcitx-5.0.19.ebuild
110
+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
A
app-i18n/fcitx/metadata.xml
16
++++++++++++++++

3 files changed, 128 insertions(+), 0 deletions(-)
diff --git a/app-i18n/fcitx/Manifest b/app-i18n/fcitx/Manifest
@@ -0,0 +1,2 @@
+DIST fcitx-5.0.19.tar.gz 1998726 BLAKE2B 60d32b3b30deb442c9653581342cf24662ac067a4a60cb76d97a0a7272a7b1f0a71de460cbad9e8b7b8256f4b113e96840adce21dee6b5eca0bcefde8f117133
+DIST fcitx-data-en_dict-20121020.tar.gz 630491 BLAKE2B 2df897b1c9fb3a2ce186ee590e5f3ccbc7930f047218bf0fefa317f74b3287fc0be9c393d3310fe07208379118ec4c46608a1c703ef37b3aee65b2d790cb7f0d
diff --git a/app-i18n/fcitx/fcitx-5.0.19.ebuild b/app-i18n/fcitx/fcitx-5.0.19.ebuild
@@ -0,0 +1,110 @@
+# Copyright 2021-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg-utils
+
+DV="20121020"
+MY_PN="fcitx5"
+DESCRIPTION="Fcitx (Flexible Context-aware Input Tool with eXtension) input method framework"
+HOMEPAGE="https://fcitx-im.org/ https://github.com/fcitx/fcitx5"
+SRC_URI="https://github.com/fcitx/fcitx5/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
+	https://download.fcitx-im.org/data/en_dict-${DV}.tar.gz -> fcitx-data-en_dict-${DV}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+KEYWORDS="~amd64 ~x86"
+IUSE="X coverage dbus doc +emoji +enchant +keyboard +libuuid +server systemd test wayland"
+REQUIRED_USE="coverage? ( test )"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	X? (
+		dev-libs/glib:2
+		x11-libs/cairo[X]
+		x11-libs/gdk-pixbuf:2
+		x11-libs/libxcb[xkb]
+		x11-libs/libxkbfile
+		x11-libs/pango[X]
+		~x11-libs/xcb-imdkit-1.0.3
+		x11-libs/xcb-util
+		x11-libs/xcb-util-keysyms
+		x11-libs/xcb-util-wm
+		)
+	dev-libs/libfmt
+	emoji? (
+		app-i18n/unicode-cldr
+		dev-libs/expat
+		)
+	enchant? ( app-text/enchant:2 )
+	keyboard? (
+		app-text/iso-codes
+		dev-libs/expat
+		dev-libs/json-c
+		x11-libs/libxkbcommon[X?]
+		x11-misc/xkeyboard-config
+		)
+	libuuid? ( sys-apps/util-linux )
+	sys-devel/gettext
+	systemd? ( sys-apps/systemd )
+	!systemd? (
+		dbus? ( sys-apps/dbus )
+		dev-libs/libevent
+		)
+	virtual/libintl
+	wayland? (
+		dev-libs/glib:2
+		dev-libs/wayland
+		dev-libs/wayland-protocols
+		dev-util/wayland-scanner
+		x11-libs/cairo
+		x11-libs/gdk-pixbuf:2
+		x11-libs/pango
+		)
+"
+RDEPEND="${DEPEND}
+"
+BDEPEND="
+	doc? ( app-doc/doxygen )
+	kde-frameworks/extra-cmake-modules
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+PATCHES=(
+	"${FILESDIR}/${PN}-5.0.8-fix-conflicts-with-fcitx4.diff"
+)
+
+src_prepare() {
+	cp "${DISTDIR}/fcitx-data-en_dict-${DV}.tar.gz" src/modules/spell/en_dict-${DV}.tar.gz || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_TEST=$(usex test)
+		-DENABLE_COVERAGE=$(usex coverage)
+		-DENABLE_ENCHANT=$(usex enchant)
+		-DENABLE_X11=$(usex X)
+		-DENABLE_WAYLAND=$(usex wayland)
+		-DENABLE_DBUS=$(usex dbus)
+		-DENABLE_SERVER=$(usex server)
+		-DENABLE_KEYBOARD=$(usex keyboard)
+		-DENABLE_EMOJI=$(usex emoji)
+		-DENABLE_LIBUUID=$(usex libuuid)
+		-DENABLE_DOC=$(usex doc)
+		-DUSE_SYSTEMD=$(usex systemd)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
diff --git a/app-i18n/fcitx/metadata.xml b/app-i18n/fcitx/metadata.xml
@@ -0,0 +1,16 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<upstream>
+		<remote-id type="github">fcitx/fcitx5</remote-id>
+		<bugs-to>https://github.com/fcitx/fcitx5/issues</bugs-to>
+	</upstream>
+	<use>
+		<flag name="coverage">Build the project with gcov support</flag>
+		<flag name="enchant">Enable Enchant backend (using <pkg>app-text/enchant</pkg>) for spelling hinting</flag>
+		<flag name="server">Build a fcitx as server, disable this option if you want to use fcitx as an embedded library</flag>
+		<flag name="keyboard">Enable key event translation with XKB and build keyboard engine</flag>
+		<flag name="emoji">Enable emoji loading for CLDR</flag>
+		<flag name="libuuid">Use libuuid for uuid generation</flag>
+	</use>
+</pkgmetadata>