logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

wxGTK-3.1.5.ebuild (3631B)

    

  1. # Copyright 1999-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. inherit multilib-minimal
  8. DESCRIPTION="GTK+ version of wxWidgets, a cross-platform C++ GUI toolkit"
  9. HOMEPAGE="https://wxwidgets.org/"
  10. SRC_URI="
  11. 	https://github.com/wxWidgets/wxWidgets/releases/download/v${PV}/wxWidgets-${PV}.tar.bz2
  12. 	doc? ( https://github.com/wxWidgets/wxWidgets/releases/download/v${PV}/wxWidgets-${PV}-docs-html.tar.bz2 )"
  13. S="${WORKDIR}/wxWidgets-${PV}"
  15. LICENSE="wxWinLL-3 GPL-2 doc? ( wxWinFDL-3 )"
  16. SLOT="3.1"
  17. KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
  18. IUSE="+X doc debug gstreamer libnotify opengl sdl tiff webkit"
  20. RDEPEND="
  21. 	>=app-eselect/eselect-wxwidgets-20131230
  22. 	dev-libs/expat[${MULTILIB_USEDEP}]
  23. 	sdl? ( media-libs/libsdl2[${MULTILIB_USEDEP}] )
  24. 	>=dev-libs/glib-2.22:2[${MULTILIB_USEDEP}]
  25. 	media-libs/libpng:0=[${MULTILIB_USEDEP}]
  26. 	sys-libs/zlib[${MULTILIB_USEDEP}]
  27. 	virtual/jpeg:0=[${MULTILIB_USEDEP}]
  28. 	x11-libs/cairo[${MULTILIB_USEDEP}]
  29. 	x11-libs/gtk+:3[${MULTILIB_USEDEP}]
  30. 	x11-libs/gdk-pixbuf[${MULTILIB_USEDEP}]
  31. 	x11-libs/pango[${MULTILIB_USEDEP}]
  32. 	X? (
  33. 		x11-libs/libSM[${MULTILIB_USEDEP}]
  34. 		x11-libs/libX11[${MULTILIB_USEDEP}]
  35. 		x11-libs/libXxf86vm[${MULTILIB_USEDEP}]
  36. 	)
  37. 	gstreamer? (
  38. 		media-libs/gstreamer:1.0[${MULTILIB_USEDEP}]
  39. 		media-libs/gst-plugins-base:1.0[${MULTILIB_USEDEP}]
  40. 	)
  41. 	libnotify? ( x11-libs/libnotify[${MULTILIB_USEDEP}] )
  42. 	opengl? ( virtual/opengl[${MULTILIB_USEDEP}] )
  43. 	tiff? ( media-libs/tiff:0[${MULTILIB_USEDEP}] )
  44. 	webkit? ( net-libs/webkit-gtk:4 )
  45. 	"
  46. DEPEND="${RDEPEND}
  47. 	opengl? ( virtual/glu[${MULTILIB_USEDEP}] )
  48. 	X? ( x11-base/xorg-proto )"
  49. BDEPEND="
  50. 	>=app-eselect/eselect-wxwidgets-20131230
  51. 	virtual/pkgconfig"
  53. src_prepare() {
  54. 	default
  56. 	use X || sed -i \
  57. 		-e 's;-lGL\b;-lOpenGL;' \
  58. 		-e 's;-lX11;;g' \
  59. 		configure || die
  60. }
  62. multilib_src_configure() {
  63. 	local myeconfargs=(
  64. 		--with-zlib=sys
  65. 		--with-expat=sys
  66. 		--enable-compat30
  67. 		$(use_with sdl)
  68. 		--enable-graphics_ctx
  69. 		--with-gtkprint
  70. 		--enable-gui
  71. 		--with-gtk=3
  72. 		--with-libpng=sys
  73. 		--with-libjpeg=sys
  74. 		--without-gnomevfs
  75. 		$(use_enable gstreamer mediactrl)
  76. 		$(multilib_native_use_enable webkit webview)
  77. 		$(use_with libnotify)
  78. 		$(use_with opengl)
  79. 		$(use_with tiff libtiff sys)
  81. 		# Don't hard-code libdir's prefix for wx-config
  82. 		--libdir='${prefix}'/$(get_libdir)
  83. 	)
  85. 	# debug in >=2.9
  86. 	# there is no longer separate debug libraries (gtk2ud)
  87. 	# wxDEBUG_LEVEL=1 is the default and we will leave it enabled
  88. 	# wxDEBUG_LEVEL=2 enables assertions that have expensive runtime costs.
  89. 	# apps can disable these features by building w/ -NDEBUG or wxDEBUG_LEVEL_0.
  90. 	# http://docs.wxwidgets.org/3.0/overview_debugging.html
  91. 	# https://groups.google.com/group/wx-dev/browse_thread/thread/c3c7e78d63d7777f/05dee25410052d9c
  92. 	use debug && myeconfargs+=( --enable-debug=max )
  94. 	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
  95. }
  97. multilib_src_install_all() {
  98. 	cd docs || die
  99. 	dodoc changes.txt readme.txt
  100. 	newdoc base/readme.txt base_readme.txt
  101. 	newdoc gtk/readme.txt gtk_readme.txt
  103. 	use doc && HTML_DOCS=( "${WORKDIR}"/wxWidgets-${PV}-docs-html/. )
  104. 	einstalldocs
  106. 	# Unversioned links
  107. 	rm "${ED}"/usr/bin/wx-config || die
  108. 	rm "${ED}"/usr/bin/wxrc || die
  110. 	# version bakefile presets
  111. 	pushd "${ED}"/usr/share/bakefile/presets >/dev/null || die
  112. 	local f
  113. 	for f in wx*; do
  114. 		mv "${f}" "${f/wx/wx31}" || die
  115. 	done
  116. 	popd >/dev/null || die
  117. }
  119. pkg_postinst() {
  120. 	has_version -b app-eselect/eselect-wxwidgets \
  121. 		&& eselect wxwidgets update
  122. }
  124. pkg_postrm() {
  125. 	has_version -b app-eselect/eselect-wxwidgets \
  126. 		&& eselect wxwidgets update
  127. }