logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

xwayland-9999.ebuild (1975B)

    

  1. # Copyright 2021-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. inherit meson git-r3
  8. DESCRIPTION="Standalone X server running under Wayland"
  9. HOMEPAGE="https://wayland.freedesktop.org/xserver.html"
  10. EGIT_REPO_URI="https://gitlab.freedesktop.org/xorg/xserver.git"
  12. IUSE="selinux video_cards_nvidia unwind xcsecurity"
  14. LICENSE="MIT"
  15. SLOT="0"
  17. DEPEND="
  18. 	>=x11-libs/pixman-0.27.2
  19. 	dev-libs/libbsd
  20. 	>=x11-libs/libXfont2-2.0.1
  21. 	dev-libs/openssl:=
  22. 	dev-libs/wayland
  23. 	video_cards_nvidia? ( gui-libs/egl-wayland )
  24. 	>=x11-libs/libXdmcp-1.0.2
  25. 	>=x11-libs/libdrm-2.4.89
  26. 	>=media-libs/libepoxy-1.5.4[X,egl(+)]
  27. 	>=media-libs/mesa-21.1[X(+),egl(+),gbm(+)]
  28. 	>=x11-libs/libxshmfence-1.1
  29. 	>=x11-libs/libXau-1.0.4
  30. 	media-libs/libglvnd[X]
  31. 	unwind? ( sys-libs/libunwind )
  32. 	>=dev-libs/wayland-protocols-1.18
  33. 	media-fonts/font-util
  34. 	x11-libs/libxkbfile
  35. 	>=x11-libs/xtrans-1.3.5
  36. 	x11-base/xorg-proto
  37. 	>=x11-misc/xkeyboard-config-2.4.1-r3
  38. 	x11-libs/libxcvt
  39. "
  41. RDEPEND="
  42. 	${DEPEND}
  43. 	x11-apps/xkbcomp
  44. 	!<=x11-base/xorg-server-1.20.11
  45. 	selinux? ( sec-policy/selinux-xserver )
  46. "
  47. BDEPEND="
  48. 	sys-devel/flex
  49. 	dev-util/wayland-scanner
  50. "
  52. src_prepare() {
  53. 	default
  55. 	sed -i '/install_man(/,/))/d' meson.build \
  56. 	|| die "Failed to remove Xserver.1 install target"
  58. 	sed -i '/install_data/,/)/d' dix/meson.build \
  59. 	|| die "Failed to remove protocols.txt install target"
  60. }
  62. src_configure() {
  63. 	local emesonargs=(
  64. 		$(meson_use selinux xselinux)
  65. 		$(meson_use unwind libunwind)
  66. 		$(meson_use xcsecurity)
  67. 		$(meson_use video_cards_nvidia xwayland_eglstream)
  68. 		-Ddpms=true
  69. 		-Ddri3=true
  70. 		-Ddtrace=false
  71. 		-Dglamor=true
  72. 		-Dglx=true
  73. 		-Dipv6=true
  74. 		-Dsecure-rpc=false
  75. 		-Dscreensaver=true
  76. 		-Dsha1=libcrypto
  77. 		-Dxace=true
  78. 		-Dxdmcp=true
  79. 		-Dxinerama=true
  80. 		-Dxvfb=false
  81. 		-Dxnest=false
  82. 		-Dxwayland-path="${EPREFIX}"/usr/bin
  83. 		-Dxorg=false
  84. 		-Dxwayland=true
  85. 	)
  87. 	meson_src_configure
  88. }
  90. src_install() {
  91. 	dosym ../bin/Xwayland /usr/libexec/Xwayland
  93. 	meson_src_install
  94. }