logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

lightspark-0.8.3.ebuild (2527B)

    

  1. # Copyright 1999-2020 Gentoo Authors

  2. # Distributed under the terms of the GNU General Public License v2

  3. 

  4. EAPI=7

  5. inherit cmake toolchain-funcs xdg-utils

  6. 

  7. DESCRIPTION="High performance flash player"

  8. HOMEPAGE="https://lightspark.github.io/"

  9. SRC_URI="https://github.com/lightspark/lightspark/archive/${PV}.tar.gz -> ${P}.tar.gz"

  10. 

  11. LICENSE="LGPL-3"

  12. SLOT="0"

  13. KEYWORDS="~amd64 ~x86"

  14. IUSE="cpu_flags_x86_sse2 curl ffmpeg gles2-only nsplugin ppapi profile rtmp"

  15. 

  16. # Note: no LLVM since it's broken upstream

  17. RDEPEND="app-arch/xz-utils:0=

  18. 	dev-cpp/glibmm:2=

  19. 	dev-libs/glib:2=

  20. 	dev-libs/libpcre:3=[cxx]

  21. 	media-fonts/liberation-fonts

  22. 	media-libs/freetype:2=

  23. 	media-libs/libpng:0=

  24. 	media-libs/libsdl2:0=

  25. 	media-libs/sdl2-mixer:0=

  26. 	sys-libs/zlib:0=

  27. 	x11-libs/cairo:0=

  28. 	x11-libs/libX11:0=

  29. 	x11-libs/pango:0=

  30. 	virtual/jpeg:0=

  31. 	curl? ( net-misc/curl:0= )

  32. 	ffmpeg?	( media-video/ffmpeg:0= )

  33. 	gles2-only? ( media-libs/mesa:0=[gles2] )

  34. 	!gles2-only? (

  35. 		>=media-libs/glew-1.5.3:0=

  36. 		virtual/opengl:0=

  37. 	)

  38. 	rtmp? ( media-video/rtmpdump:0= )"

  39. DEPEND="${RDEPEND}

  40. 	amd64? ( dev-lang/nasm )

  41. 	x86? ( dev-lang/nasm )

  42. 	virtual/pkgconfig"

  43. 

  44. S=${WORKDIR}/${P/_rc*/}

  45. 

  46. src_configure() {

  47. 	local mycmakeargs=(

  48. 		-DENABLE_CURL=$(usex curl)

  49. 		-DENABLE_GLES2=$(usex gles2-only)

  50. 		-DENABLE_LIBAVCODEC=$(usex ffmpeg)

  51. 		-DENABLE_RTMP=$(usex rtmp)

  52. 

  53. 		-DENABLE_MEMORY_USAGE_PROFILING=$(usex profile)

  54. 		-DENABLE_PROFILING=$(usex profile)

  55. 		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)

  56. 

  57. 		-DCOMPILE_NPAPI_PLUGIN=$(usex nsplugin)

  58. 		-DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins

  59. 		# TODO: install /etc/chromium file? block adobe-flash?

  60. 		-DCOMPILE_PPAPI_PLUGIN=$(usex ppapi)

  61. 		-DPPAPI_PLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/chromium-browser/${PN}

  62. 	)

  63. 

  64. 	cmake_src_configure

  65. }

  66. 

  67. src_install() {

  68. 	cmake_src_install

  69. 

  70. 	if use nsplugin; then

  71. 		# copied from nsplugins.eclass, that's broken in EAPI 7

  72. 		dodir /usr/$(get_libdir)/nsbrowser/plugins

  73. 		dosym ../../lightspark/plugins/liblightsparkplugin.so \

  74. 			/usr/$(get_libdir)/nsbrowser/plugins/liblightsparkplugin.so

  75. 	fi

  76. }

  77. 

  78. pkg_postinst() {

  79. 	xdg_icon_cache_update

  80. 	xdg_desktop_database_update

  81. 

  82. 	if use nsplugin && has_version "www-plugins/gnash[nsplugin]"; then

  83. 		elog "Having two plugins installed for the same MIME type may confuse"

  84. 		elog "Mozilla based browsers. It is recommended to disable the nsplugin"

  85. 		elog "USE flag for either gnash or lightspark. For details, see"

  86. 		elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"

  87. 	fi

  88. }

  89. 

  90. pkg_postrm() {

  91. 	xdg_icon_cache_update

  92. 	xdg_desktop_database_update

  93. }