logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

visurf-9999.ebuild (2823B)

    

  1. # Copyright 1999-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. inherit netsurf desktop git-r3
  8. DESCRIPTION="power-user frontend for netsurf"
  9. HOMEPAGE="https://git.sr.ht/~sircmpwn/visurf"
  10. EGIT_REPO_URI="https://git.sr.ht/~sircmpwn/visurf"
  12. LICENSE="GPL-2 MIT"
  13. SLOT="0"
  14. KEYWORDS=""
  15. IUSE="bmp duktape truetype +gif javascript +jpeg mng
  16. 	+png +psl rosprite +svg +svgtiny +webp"
  18. REQUIRED_USE="duktape? ( javascript )"
  20. RDEPEND="
  21. 	>=dev-libs/libcss-9999
  22. 	>=net-libs/libdom-0.3
  23. 	>=net-libs/libhubbub-0.3
  24. 	>=dev-libs/libnsutils-0.1.0
  25. 	dev-libs/libxml2:2
  26. 	net-misc/curl
  27. 	dev-libs/wayland
  28. 	x11-libs/cairo
  29. 	x11-libs/pango
  30. 	x11-libs/libxkbcommon
  31. 	dev-libs/libutf8proc:=
  32. 	bmp? ( >=media-libs/libnsbmp-0.1 )
  33. 	gif? ( >=media-libs/libnsgif-0.1 )
  34. 	javascript? (
  35. 		>=dev-libs/nsgenbind-0.7
  36. 		duktape? ( dev-lang/duktape:= )
  37. 		!duktape? ( dev-lang/spidermonkey:0= )
  38. 	)
  39. 	jpeg? ( >=virtual/jpeg-0-r2:0 )
  40. 	mng? ( >=media-libs/libmng-1.0.10-r2 )
  41. 	png? ( >=media-libs/libpng-1.2.51:0 )
  42. 	psl? ( media-libs/libnspsl )
  43. 	rosprite? ( >=media-libs/librosprite-0.1.2-r1 )
  44. 	svg? ( svgtiny? ( >=media-libs/libsvgtiny-0.1.3-r1 )
  45. 		!svgtiny? ( gnome-base/librsvg:2 ) )
  46. 	webp? ( >=media-libs/libwebp-0.3.0 )
  47. "
  48. DEPEND="${RDEPEND}"
  49. BDEPEND="
  50. 	duktape? ( app-editors/vim-core )
  51. 	dev-libs/check
  52. 	dev-perl/HTML-Parser
  53. 	>=dev-util/netsurf-buildsystem-1.7-r1
  54. 	virtual/pkgconfig
  55. 	dev-libs/wayland-protocols
  56. "
  58. PATCHES=(
  59. 	"${FILESDIR}/netsurf-3.10-julia-libutf8proc-header-location.patch"
  60. )
  62. src_prepare() {
  63. 	default
  64. 	# do not delete gtk frontend, virsurf/res uses gtk/res
  65. 	rm -r frontends/{amiga,atari,beos,monkey,riscos,windows,framebuffer} || die
  66. 	mkdir -p build/Linux-visurf || die
  67. }
  69. _emake() {
  70. 	netsurf_define_makeconf
  71. 	local netsurf_makeconf=(
  72. 		"${NETSURF_MAKECONF[@]}"
  73. 		COMPONENT_TYPE=binary
  74. 		NETSURF_USE_BMP=$(usex bmp YES NO)
  75. 		NETSURF_USE_GIF=$(usex gif YES NO)
  76. 		NETSURF_USE_JPEG=$(usex jpeg YES NO)
  77. 		NETSURF_USE_PNG=$(usex png YES NO)
  78. 		NETSURF_USE_NSPSL=$(usex psl YES NO)
  79. 		NETSURF_USE_MNG=$(usex mng YES NO)
  80. 		NETSURF_USE_WEBP=$(usex webp YES NO)
  81. 		NETSURF_USE_MOZJS=$(usex javascript $(usex duktape NO YES) NO)
  82. 		NETSURF_USE_JS=NO
  83. 		NETSURF_USE_DUKTAPE=$(usex javascript $(usex duktape YES NO) NO)
  84. 		NETSURF_USE_NSSVG=$(usex svg $(usex svgtiny YES NO) NO)
  85. 		NETSURF_USE_RSVG=$(usex svg $(usex svgtiny NO YES) NO)
  86. 		NETSURF_USE_ROSPRITE=$(usex rosprite YES NO)
  87. 		PKG_CONFIG=$(tc-getPKG_CONFIG)
  88. 		NETSURF_FB_FONTLIB=$(usex truetype freetype internal)
  89. 		NETSURF_FB_FONTPATH="${EPREFIX}/usr/share/fonts/dejavu"
  90. 		NETSURF_USE_VIDEO=NO
  91. 		TARGET=visurf
  92. 	)
  93. 	emake "${netsurf_makeconf[@]}" $@
  94. }
  96. src_compile() {
  97. 	_emake
  98. }
  100. src_test() {
  101. 	_emake test
  102. }
  104. src_install() {
  105. 	_emake DESTDIR="${D}" install
  106. 	make_desktop_entry "${EPREFIX}"/usr/bin/netsurf-vi \
  107. 		NetSurf-vi \
  108. 		netsurf \
  109. 		"Network;WebBrowser"
  110. }