logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

pleroma-2.5.2.ebuild (3057B)

    

  1. # Copyright 2022-2023 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. inherit mix optfeature
  8. DESCRIPTION="ActivityPub social networking software compatible with other Fediverse software"
  9. HOMEPAGE="https://pleroma.social/"
  10. if [[ "${PV}" == *9999 ]]; then
  11. 	inherit git-r3
  12. 	EGIT_REPO_URI="https://git.pleroma.social/pleroma/pleroma"
  13. 	# git-r3 doesn't allows make.conf override of MIN_CLONE_TYPE, so done here for my self-hosted branch
  14. 	EGIT_MIN_CLONE_TYPE="single+tags"
  15. else
  16. 	SRC_URI="https://git.pleroma.social/pleroma/pleroma/-/archive/v${PV}/${PN}-v${PV}.tar.gz"
  17. 	S="${WORKDIR}/${PN}-v${PV}"
  18. fi
  19. LICENSE="AGPL-3 CC-BY-SA-4.0 CC-BY-4.0"
  20. SLOT="otp"
  21. KEYWORDS="~amd64"
  22. IUSE=""
  24. # Requires network access (https) as long as elixir dependencies aren't packaged
  25. # said dependencies have their checksum verified via `mix.lock`
  26. RESTRICT="network-sandbox"
  28. BDEPEND="
  29. 	dev-lang/erlang:=
  30. 	dev-lang/elixir:=
  31. 	dev-util/cmake
  32. 	dev-util/rebar
  33. 	dev-elixir/hex
  34. "
  35. DEPEND="
  36. 	sys-libs/ncurses:=
  37. 	sys-apps/file
  38. "
  39. RDEPEND="
  40. 	${DEPEND}
  41. 	acct-user/pleroma
  42. 	acct-group/pleroma
  43. 	dev-db/postgresql[uuid]
  44. "
  46. src_unpack() {
  47. 	default
  49. 	[[ "${PV}" == *9999 ]] && git-r3_src_unpack
  51. 	cd "${S}" || die
  52. 	emix deps.get --only prod
  53. }
  55. src_prepare() {
  56. 	default
  58. 	# Point to the correct source repo, needed for AGPL compliance
  59. 	if [[ "${PV}" == *9999 ]] && [[ -n "${EGIT_OVERRIDE_REPO}" ]]; then
  60. 		sed -i "s!source_url: .*!source_url: \"${EGIT_OVERRIDE_REPO}\",!" mix.exs || die
  61. 	fi
  63. 	sed -i -e '/include_executables_for:/a\          strip_beams: false,\n\          include_erts: false,' mix.exs || die
  65. 	sed -i \
  66. 		-e '/update \[OPTIONS\]/,/--tmp-dir/d' \
  67. 		-e 's;update "$@";echo "Unsupported, check the '"${CATEGORY}/${PN}"' package instead.";' \
  68. 		rel/files/bin/pleroma_ctl || die
  70. 	# Default ends up being inside /opt/pleroma which should be kept read-only to pleroma
  71. 	echo 'config :tzdata, :data_dir, "/var/lib/pleroma/tzdata"' >> config/prod.exs || die
  73. 	echo "import Config" > config/prod.secret.exs || die
  74. }
  76. src_compile() {
  77. 	mkdir -p pleroma || die
  78. 	emix release --overwrite --path pleroma
  79. }
  81. src_install() {
  82. 	# doins doesn't seems to preserve permissions
  83. 	mkdir -p "${ED}/opt" || die
  84. 	cp -pr ./pleroma "${ED}/opt/pleroma" || die
  85. 	fperms 0750 /opt/pleroma
  86. 	fowners 0:pleroma /opt/pleroma
  88. 	dosym /opt/pleroma/bin/pleroma /usr/bin/pleroma
  89. 	dosym /opt/pleroma/bin/pleroma_ctl /usr/bin/pleroma_ctl
  91. 	# This file controls console access
  92. 	fperms 0750 /opt/pleroma/releases/COOKIE
  93. 	fowners 0:pleroma /opt/pleroma/releases/COOKIE
  95. 	keepdir /etc/pleroma
  96. 	fperms 0750 /etc/pleroma
  97. 	fowners 0:pleroma /etc/pleroma
  99. 	keepdir /var/lib/pleroma
  100. 	fperms 0750 /var/lib/pleroma
  101. 	fowners pleroma:pleroma /var/lib/pleroma
  102. }
  104. pkg_postinst() {
  105. 	optfeature "For Pleroma.Upload.Filters.{Mogrify,Mogrifun} and still image support in Media Preview Proxy" media-gfx/imagemagick
  106. 	optfeature "For video support in Media Preview Proxy" media-video/ffmpeg
  107. 	optfeature "For Pleroma.Upload.Filters.Exiftool.* filters" media-libs/exiftool
  108. }