logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

gettext-0.3.2-r5.ebuild (1516B)

    

  1. # Copyright 2022-2024 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit toolchain-funcs multilib-minimal
  8. DESCRIPTION="Stub and/or lightweight replacements of the GNU gettext suite"
  9. HOMEPAGE="https://github.com/sabotage-linux/gettext-tiny"
  10. SRC_URI="https://github.com/sabotage-linux/gettext-tiny/archive/refs/tags/v${PV}.tar.gz -> gettext-tiny-${PV}.tar.gz"
  11. S="${WORKDIR}/gettext-tiny-${PV}/"
  13. LICENSE="MIT"
  14. SLOT="tiny"
  15. KEYWORDS="~amd64"
  16. IUSE="shim"
  18. RDEPEND="!<sys-devel/gettext-666:0"
  20. PATCHES=(
  21. 	"${FILESDIR}"/gettext-0.3.2-respect-CFLAGS.patch
  22. 	"${FILESDIR}"/gettext-0.3.2-xgettext-version-output.patch
  23. 	"${FILESDIR}"/gettext-0.3.2-autopoint-parenthesis.patch
  24. 	"${FILESDIR}"/gettext-0.3.2-autopoint_serial.patch
  25. 	"${FILESDIR}"/gettext-0.3.2-autopoint_mkdir.patch
  26. )
  28. DOCS=( README.md docs )
  30. src_prepare() {
  31. 	default
  33. 	# Needs to be set early, otherwise scripts like autopoint have a wrong prefix value
  34. 	sed -i "s;^prefix=.*;prefix=${EPREFIX}/usr;" Makefile || die
  36. 	multilib_copy_sources
  37. }
  39. multilib_src_compile() {
  40. 	tc-export AR RANLIB CC
  42. 	emake
  43. }
  45. multilib_src_install() {
  46. 	local libintl_type
  48. 	if use shim ; then
  49. 		if use elibc_musl ; then
  50. 			libintl_type=MUSL
  51. 		else
  52. 			libintl_type=NOOP
  53. 		fi
  54. 	else
  55. 		# If they don't want the shim (e.g. glibc users who have their own libintl),
  56. 		# don't install a libintl and just install the binaries.
  57. 		libintl_type=NONE
  58. 	fi
  60. 	emake LIBINTL="${libintl_type}" DESTDIR="${D}" libdir="${EPREFIX}/usr/$(get_libdir)" install
  61. }