logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

gettext-0.3.2-r4.ebuild (1454B)

    

  1. # Copyright 2022-2024 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit toolchain-funcs multilib-minimal
  8. DESCRIPTION="Stub and/or lightweight replacements of the GNU gettext suite"
  9. HOMEPAGE="https://github.com/sabotage-linux/gettext-tiny"
  10. SRC_URI="https://github.com/sabotage-linux/gettext-tiny/archive/refs/tags/v${PV}.tar.gz -> gettext-tiny-${PV}.tar.gz"
  11. S="${WORKDIR}/gettext-tiny-${PV}/"
  13. LICENSE="MIT"
  14. SLOT="tiny"
  15. KEYWORDS="~amd64"
  16. IUSE="shim"
  18. RDEPEND="!sys-devel/gettext:0"
  20. PATCHES=(
  21. 	"${FILESDIR}"/gettext-0.3.2-respect-CFLAGS.patch
  22. 	"${FILESDIR}"/gettext-0.3.2-xgettext-version-output.patch
  23. 	"${FILESDIR}"/gettext-0.3.2-autopoint-parenthesis.patch
  24. 	"${FILESDIR}"/gettext-0.3.2-m4_cleanup.patch
  25. )
  27. DOCS=( README.md docs )
  29. src_prepare() {
  30. 	default
  32. 	# Needs to be set early, otherwise scripts like autopoint have a wrong prefix value
  33. 	sed -i "s;^prefix=.*;prefix=${EPREFIX}/usr;" Makefile || die
  35. 	multilib_copy_sources
  36. }
  38. multilib_src_compile() {
  39. 	tc-export AR RANLIB CC
  41. 	emake
  42. }
  44. multilib_src_install() {
  45. 	local libintl_type
  47. 	if use shim ; then
  48. 		if use elibc_musl ; then
  49. 			libintl_type=MUSL
  50. 		else
  51. 			libintl_type=NOOP
  52. 		fi
  53. 	else
  54. 		# If they don't want the shim (e.g. glibc users who have their own libintl),
  55. 		# don't install a libintl and just install the binaries.
  56. 		libintl_type=NONE
  57. 	fi
  59. 	emake LIBINTL="${libintl_type}" DESTDIR="${D}" libdir="${EPREFIX}/usr/$(get_libdir)" install
  60. }