logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

gettext-0.3.2-r3.ebuild (1408B)

    

  1. # Copyright 2022-2024 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit toolchain-funcs multilib-minimal
  8. DESCRIPTION="Stub and/or lightweight replacements of the GNU gettext suite"
  9. HOMEPAGE="https://github.com/sabotage-linux/gettext-tiny"
  10. SRC_URI="https://github.com/sabotage-linux/gettext-tiny/archive/refs/tags/v${PV}.tar.gz -> gettext-tiny-${PV}.tar.gz"
  11. S="${WORKDIR}/gettext-tiny-${PV}/"
  13. LICENSE="MIT"
  14. SLOT="tiny"
  15. KEYWORDS="~amd64"
  16. IUSE="shim"
  18. RDEPEND="!sys-devel/gettext:0"
  20. PATCHES=(
  21. 	"${FILESDIR}"/gettext-0.3.2-respect-CFLAGS.patch
  22. 	"${FILESDIR}"/gettext-0.3.2-xgettext-version-output.patch
  23. 	"${FILESDIR}"/gettext-0.3.2-autopoint-parenthesis.patch
  24. )
  26. DOCS=( README.md docs )
  28. src_prepare() {
  29. 	default
  31. 	# Needs to be set early, otherwise scripts like autopoint have a wrong prefix value
  32. 	sed -i "s;^prefix=.*;prefix=${EPREFIX}/usr;" Makefile || die
  34. 	multilib_copy_sources
  35. }
  37. multilib_src_compile() {
  38. 	tc-export AR RANLIB CC
  40. 	emake
  41. }
  43. multilib_src_install() {
  44. 	local libintl_type
  46. 	if use shim ; then
  47. 		if use elibc_musl ; then
  48. 			libintl_type=MUSL
  49. 		else
  50. 			libintl_type=NOOP
  51. 		fi
  52. 	else
  53. 		# If they don't want the shim (e.g. glibc users who have their own libintl),
  54. 		# don't install a libintl and just install the binaries.
  55. 		libintl_type=NONE
  56. 	fi
  58. 	emake LIBINTL="${libintl_type}" DESTDIR="${D}" libdir="${EPREFIX}/usr/$(get_libdir)" install
  59. }