logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

gettext-0.3.2-r2.ebuild (1236B)

    

  1. # Copyright 2022-2024 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit toolchain-funcs
  8. DESCRIPTION="Stub and/or lightweight replacements of the GNU gettext suite"
  9. HOMEPAGE="https://github.com/sabotage-linux/gettext-tiny"
  10. SRC_URI="https://github.com/sabotage-linux/gettext-tiny/archive/refs/tags/v${PV}.tar.gz -> gettext-tiny-${PV}.tar.gz"
  11. S="${WORKDIR}/gettext-tiny-${PV}/"
  13. LICENSE="MIT"
  14. SLOT="tiny"
  15. KEYWORDS="~amd64"
  16. IUSE="shim"
  18. RDEPEND="!sys-devel/gettext:0"
  20. PATCHES=(
  21. 	"${FILESDIR}"/${P}-respect-CFLAGS.patch
  22. 	"${FILESDIR}"/${P}-xgettext-version-output.patch
  23. )
  25. DOCS=( README.md docs )
  27. src_prepare() {
  28. 	default
  30. 	# Needs to be set early, otherwise scripts like autopoint have a wrong prefix value
  31. 	sed -i "s;^prefix=.*;prefix=${EPREFIX}/usr;" Makefile || die
  32. }
  34. src_compile() {
  35. 	tc-export AR RANLIB CC
  37. 	emake
  38. }
  40. src_install() {
  41. 	local libintl_type
  43. 	if use shim ; then
  44. 		if use elibc_musl ; then
  45. 			libintl_type=MUSL
  46. 		else
  47. 			libintl_type=NOOP
  48. 		fi
  49. 	else
  50. 		# If they don't want the shim (e.g. glibc users who have their own libintl),
  51. 		# don't install a libintl and just install the binaries.
  52. 		libintl_type=NONE
  53. 	fi
  55. 	emake LIBINTL="${libintl_type}" DESTDIR="${D}" install
  56. }