logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://anongit.hacktivis.me/git/overlay.git/

skeud-9999.ebuild (1639B)

    

  1. # Copyright 2021-2025 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  7. DESCRIPTION="Simple and portable utilities to deal with user accounts (su, login)"
  8. HOMEPAGE="https://hacktivis.me/git/skeud"
  9. if [[ "${PV}" = *9999* ]]; then
  10. 	inherit git-r3
  11. 	EGIT_REPO_URI="https://anongit.hacktivis.me/git/skeud.git"
  12. else
  13. 	VERIFY_SIG_METHOD=signify
  14. 	inherit verify-sig
  16. 	SRC_URI="
  17. 		https://distfiles.hacktivis.me/releases/${PN}/${P}.tar.gz
  18. 		verify-sig? ( https://distfiles.hacktivis.me/releases/${PN}/${P}.tar.gz.sign )
  19. 	"
  20. 	KEYWORDS="~amd64 ~arm64 ~riscv"
  21. fi
  22. LICENSE="MPL-2.0"
  23. SLOT="0"
  24. IUSE="static test"
  26. RESTRICT="!test? ( test )"
  28. DEPEND="virtual/libcrypt:="
  29. RDEPEND="${DEPEND}"
  30. BDEPEND="
  31. 	test? (
  32. 		dev-libs/atf
  33. 		dev-util/kyua
  34. 	)
  35. "
  37. if [[ "${PV}" != 9999* ]]
  38. then
  39. 	BDEPEND="${BDEPEND} verify-sig? ( sec-keys/signify-keys-lanodan:2025 )"
  40. 	VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/signify-keys-lanodan-2025.pub"
  42. 	src_unpack() {
  43. 		if use verify-sig; then
  44. 			# Too many levels of symbolic links workaround
  45. 			cd "${WORKDIR}" || die
  46. 			cp "${DISTDIR}/${P}.tar.gz" "${DISTDIR}/${P}.tar.gz.sign" "${WORKDIR}/" || die
  47. 			verify-sig_verify_detached "${P}.tar.gz" "${P}.tar.gz.sign"
  48. 			unpack "${WORKDIR}/${P}.tar.gz"
  49. 			rm "${WORKDIR}/${P}.tar.gz"
  50. 		else
  51. 			default
  52. 		fi
  53. 	}
  54. fi
  56. src_compile() {
  57. 	use static && export LDSTATIC='-static'
  58. 	default
  59. }
  61. src_install() {
  62. 	emake install DESTDIR="${D}" PREFIX='/opt/lanodan' SYS_BINDIR='/opt/lanodan/bin'
  64. 	# before 50baselayout
  65. 	newenvd - 40skeud <<-EOF
  66. 		PATH="/opt/lanodan/bin"
  67. 		MANPATH="/opt/lanodan/share/man"
  68. 	EOF
  69. }