logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://anongit.hacktivis.me/git/overlay.git/

skeud-0.3.0.ebuild (1865B)

    

  1. # Copyright 2021-2025 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. VERIFY_SIG_METHOD=signify
  7. inherit verify-sig
  9. DESCRIPTION="Simple and portable utilities to deal with user accounts (su, login)"
  10. HOMEPAGE="https://hacktivis.me/git/skeud"
  11. SRC_URI="
  12. 	https://distfiles.hacktivis.me/releases/${PN}/${P}.tar.gz
  13. 	verify-sig? ( https://distfiles.hacktivis.me/releases/${PN}/${P}.tar.gz.sign )
  14. "
  15. KEYWORDS="~amd64 ~arm64 ~riscv"
  16. LICENSE="MPL-2.0"
  17. SLOT="0"
  18. IUSE="suc system test"
  20. RESTRICT="!test? ( test )"
  22. DEPEND="virtual/libcrypt:="
  23. RDEPEND="
  24. 	${DEPEND}
  25. 	system? (
  26. 		!sys-apps/shadow[su]
  27. 		!sys-apps/util-linux[su]
  28. 	)
  29. "
  30. BDEPEND="
  31. 	test? (
  32. 		dev-libs/atf
  33. 		dev-util/kyua
  34. 	)
  35. "
  37. BDEPEND="${BDEPEND} verify-sig? ( sec-keys/signify-keys-lanodan:2025 )"
  38. VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/signify-keys-lanodan-2025.pub"
  40. src_unpack() {
  41. 	if use verify-sig; then
  42. 		# Too many levels of symbolic links workaround
  43. 		cd "${WORKDIR}" || die
  44. 		cp "${DISTDIR}/${P}.tar.gz" "${DISTDIR}/${P}.tar.gz.sign" "${WORKDIR}/" || die
  45. 		verify-sig_verify_detached "${P}.tar.gz" "${P}.tar.gz.sign"
  46. 		unpack "${WORKDIR}/${P}.tar.gz"
  47. 		rm "${WORKDIR}/${P}.tar.gz"
  48. 	else
  49. 		default
  50. 	fi
  51. }
  53. src_compile() {
  54. 	emake
  56. 	use suc && emake suc
  57. }
  59. src_install() {
  60. 	if use system; then
  61. 		into /
  62. 		dosbin su
  63. 		fperms 4755 sbin/su
  64. 		newsbin login skeud-login
  65. 		fperms 0755 sbin/skeud-login
  66. 		newman login.1 skeud-login.1
  68. 		if use suc; then
  69. 			dosbin suc
  70. 			fperms 4755 sbin/suc
  71. 			doman suc.1
  72. 		fi
  73. 	else
  74. 		emake install DESTDIR="${D}" PREFIX='/opt/lanodan' SYS_BINDIR='/opt/lanodan/bin'
  76. 		use suc && emake install-suc DESTDIR="${D}" PREFIX='/opt/lanodan' SYS_BINDIR='/opt/lanodan/bin'
  78. 		# before 50baselayout
  79. 		newenvd - 40skeud <<-EOF
  80. 			PATH="/opt/lanodan/bin"
  81. 			MANPATH="/opt/lanodan/share/man"
  82. 		EOF
  83. 	fi
  84. }