logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://anongit.hacktivis.me/git/overlay.git/

9utils-0.1.0.ebuild (1343B)

    

  1. # Copyright 2021-2025 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. if [[ "${PV}" = *9999* ]]; then
  7. 	inherit git-r3
  8. 	EGIT_REPO_URI="https://anongit.hacktivis.me/git/9utils.git"
  9. else
  10. 	VERIFY_SIG_METHOD=signify
  11. 	inherit verify-sig
  13. 	SRC_URI="
  14. 		https://distfiles.hacktivis.me/releases/9utils/${P}.tar.gz
  15. 		verify-sig? ( https://distfiles.hacktivis.me/releases/9utils/${P}.tar.gz.sign )
  16. 	"
  18. 	KEYWORDS="~amd64 ~arm64 ~riscv"
  19. fi
  22. DESCRIPTION="Collection of utilities inspired by Plan9"
  23. HOMEPAGE="https://hacktivis.me/git/9utils"
  24. LICENSE="MPL-2.0"
  25. SLOT="0"
  26. IUSE="test"
  28. RESTRICT="!test? ( test )"
  30. RDEPEND="dev-lang/hare:="
  31. DEPEND="${RDEPEND}"
  32. BDEPEND="test? ( dev-util/cram )"
  34. if [[ "${PV}" != 9999* ]]
  35. then
  36. 	BDEPEND="${BDEPEND} verify-sig? ( sec-keys/signify-keys-lanodan:2025 )"
  38. 	VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/signify-keys/signify-keys-lanodan-2025.pub"
  40. 	src_unpack() {
  41. 		if use verify-sig; then
  42. 			# Too many levels of symbolic links workaround
  43. 			cd "${WORKDIR}" || die
  44. 			cp "${DISTDIR}/${P}.tar.gz" "${DISTDIR}/${P}.tar.gz.sign" "${WORKDIR}/" || die
  45. 			verify-sig_verify_detached "${P}.tar.gz" "${P}.tar.gz.sign"
  46. 			unpack "${WORKDIR}/${P}.tar.gz"
  47. 			rm "${WORKDIR}/${P}.tar.gz"
  48. 		else
  49. 			default
  50. 		fi
  51. 	}
  52. fi
  54. src_install() {
  55. 	PREFIX=/usr default
  56. }