logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

streamlink-3.0.3.ebuild (1448B)

    

  1. # Copyright 1999-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. PYTHON_COMPAT=( python3_{8..9} )
  7. PYTHON_REQ_USE='xml(+),threads(+)'
  8. DISTUTILS_SINGLE_IMPL=1
  9. inherit distutils-r1
  11. DESCRIPTION="CLI for extracting streams from websites to a video player of your choice"
  12. HOMEPAGE="https://streamlink.github.io/"
  14. if [[ ${PV} = 9999* ]]; then
  15. 	EGIT_REPO_URI="https://github.com/streamlink/${PN}.git"
  16. 	inherit git-r3
  17. else
  18. 	SRC_URI="https://github.com/streamlink/${PN}/releases/download/${PV}/${P}.tar.gz"
  19. 	KEYWORDS="~amd64 ~x86"
  20. fi
  22. LICENSE="BSD-2 Apache-2.0"
  23. SLOT="0"
  24. IUSE="test"
  25. RESTRICT="!test? ( test )"
  27. DEPEND="
  28. 	$(python_gen_cond_dep '
  29. 		dev-python/isodate[${PYTHON_USEDEP}]
  30. 		>=dev-python/lxml-4.6.4[${PYTHON_USEDEP}]
  31. 		dev-python/pycountry[${PYTHON_USEDEP}]
  32. 		>=dev-python/pycryptodome-3.4.3[${PYTHON_USEDEP}]
  33. 		>=dev-python/PySocks-1.5.8[${PYTHON_USEDEP}]
  34. 		>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
  35. 		>=dev-python/websocket-client-1.2.1[${PYTHON_USEDEP}]
  36. 	')
  37. "
  39. RDEPEND="${DEPEND}
  40. 	media-video/ffmpeg
  41. "
  43. BDEPEND="
  44. 	$(python_gen_cond_dep '
  45. 		test? (
  46. 			dev-python/mock[${PYTHON_USEDEP}]
  47. 			dev-python/requests-mock[${PYTHON_USEDEP}]
  48. 			>=dev-python/freezegun-1.0.0[${PYTHON_USEDEP}]
  49. 			dev-python/freezegun[${PYTHON_USEDEP}]
  50. 		)
  51. 	')"
  53. distutils_enable_tests pytest
  55. python_configure_all() {
  56. 	# Avoid iso-639, iso3166 dependencies since we use pycountry.
  57. 	export STREAMLINK_USE_PYCOUNTRY=1
  58. }