logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

wpewebkit-2.32.3.ebuild (2937B)

    

  1. # Copyright 1999-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  5. CMAKE_MAKEFILE_GENERATOR="ninja"
  6. PYTHON_COMPAT=( python3_{7..9} )
  7. USE_RUBY="ruby24 ruby25 ruby26 ruby27 ruby30"
  9. inherit cmake python-any-r1 ruby-single
  11. DESCRIPTION="WebKit port optimized for embedded devices"
  12. HOMEPAGE="https://wpewebkit.org/"
  13. LICENSE="LGPL-2+ BSD"
  14. SRC_URI="https://wpewebkit.org/releases/${P}.tar.xz"
  15. SLOT="1.0" # WPE_API_VERSION
  16. KEYWORDS="~amd64"
  17. IUSE="accessibility doc examples experimental jpeg2k qt +gstreamer sandbox systemd +webdriver +webcrypto X"
  19. RDEPEND="
  20. 	>=x11-libs/cairo-1.16.0:=[X?]
  21. 	>=media-libs/fontconfig-2.13.0:=
  22. 	>=media-libs/freetype-2.9.0:=
  23. 	>=dev-libs/glib-2.44.0:=
  24. 	>=media-libs/harfbuzz-1.4.2:=[icu(+)]
  25. 	>=dev-libs/icu-60.2:=
  26. 	virtual/jpeg:0=
  27. 	>=media-libs/libepoxy-1.4.0:=
  28. 	>=dev-libs/libgcrypt-1.7.0:=
  29. 	>=net-libs/libsoup-2.54.0:=
  30. 	>=dev-libs/libxml2-2.8.0:=
  31. 	media-libs/libpng:=
  32. 	dev-db/sqlite:3=
  33. 	media-libs/libwebp:=
  34. 	gui-libs/libwpe:=
  35. 	sys-libs/zlib:=
  37. 	>=dev-libs/libxslt-1.1.7
  38. 	>=media-libs/woff2-1.0.2
  40. 	jpeg2k? ( >=media-libs/openjpeg-2.2.0:2= )
  41. 	webcrypto? (
  42. 		dev-libs/libtasn1:=
  43. 		>=dev-libs/libgcrypt-1.7.0:=
  44. 	)
  45. 	qt? (
  46. 		dev-qt/qtcore:5=
  47. 		dev-qt/qtquickcontrols:5=
  48. 		dev-qt/qtgui:5=
  49. 		dev-qt/qttest:5=
  50. 		>=gui-libs/wpebackend-fdo-1.3.0:=
  51. 	)
  52. 	gstreamer? (
  53. 		>=media-libs/gstreamer-1.16:1.0
  54. 		>=media-libs/gst-plugins-base-1.16:1.0[egl]
  55. 		>=media-plugins/gst-plugins-opus-1.16:1.0
  56. 		>=media-libs/gst-plugins-bad-1.16:1.0
  57. 	)
  58. 	accessibility? (
  59. 		>=dev-libs/atk-2.16.0:=
  60. 		app-accessibility/at-spi2-atk:=
  61. 	)
  62. 	sandbox? ( sys-apps/bubblewrap )
  63. 	systemd? ( sys-apps/systemd:= )
  64. "
  65. DEPEND="
  66. 	${RDEPEND}
  67. 	${PYTHON_DEPS}
  68. 	${RUBY_DEPS}
  70. 	>=dev-lang/perl-5.10
  71. 	virtual/perl-JSON-PP
  73. 	doc? ( >=dev-util/gtk-doc-1.10 )
  74. "
  76. src_configure() {
  77. 	# Ruby situation is a bit complicated. See bug 513888
  78. 	local rubyimpl
  79. 	local ruby_interpreter=""
  80. 	for rubyimpl in ${USE_RUBY}; do
  81. 		if has_version -b "virtual/rubygems[ruby_targets_${rubyimpl}]"; then
  82. 			ruby_interpreter="-DRUBY_EXECUTABLE=$(type -P ${rubyimpl})"
  83. 		fi
  84. 	done
  85. 	# This will rarely occur. Only a couple of corner cases could lead us to
  86. 	# that failure. See bug 513888
  87. 	[[ -z $ruby_interpreter ]] && die "No suitable ruby interpreter found"
  89. 	local mycmakeargs=(
  90. 		"-DPORT=WPE"
  91. 		-DENABLE_ACCESSIBILITY=$(usex accessibility)
  92. 		-DENABLE_BUBBLEWRAP_SANDBOX=$(usex sandbox)
  93. 		-DUSE_WOFF2=ON
  94. 		-DSHOULD_INSTALL_JS_SHELL=ON
  95. 		-DENABLE_ENCRYPTED_MEDIA=OFF
  96. 		-DENABLE_EXPERIMENTAL_FEATURES=$(usex experimental)
  97. 		-DENABLE_GTKDOC=$(usex doc)
  98. 		-DUSE_OPENJPEG=$(usex jpeg2k)
  99. 		-DENABLE_WPE_QT_API=$(usex qt)
  100. 		-DENABLE_MINIBROWSER=$(usex examples)
  101. 		-DENABLE_VIDEO=$(usex gstreamer)
  102. 		-DENABLE_WEB_AUDIO=$(usex gstreamer)
  103. 		-DENABLE_WEBDRIVER=$(usex webdriver)
  104. 		-DENABLE_WEB_CRYPTO=$(usex webcrypto)
  105. 		-DENABLE_XSLT=ON
  106. 		-DUSE_SYSTEMD=$(usex systemd) # Whether to enable journald logging
  107. 		${ruby_interpreter}
  108. 	)
  110. 	cmake_src_configure
  111. }