logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

libsoup-3.0.8.ebuild (3141B)

    

  1. # Copyright 1999-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  5. VALA_MIN_API_VERSION="0.54" # requires gio-2.0.vapi generated from glib-2.70+
  7. inherit gnome.org meson-multilib vala xdg
  9. DESCRIPTION="HTTP client/server library for GNOME"
  10. HOMEPAGE="https://wiki.gnome.org/Projects/libsoup"
  12. LICENSE="LGPL-2.1+"
  13. SLOT="3.0"
  15. IUSE="+brotli gssapi gtk-doc +introspection samba ssl sysprof test +vala"
  16. RESTRICT="!test? ( test )"
  17. REQUIRED_USE="vala? ( introspection )"
  19. KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
  21. DEPEND="
  22. 	>=dev-libs/glib-2.69.1:2[${MULTILIB_USEDEP}]
  23. 	net-libs/nghttp2:=[${MULTILIB_USEDEP}]
  24. 	>=dev-db/sqlite-3.8.2:3[${MULTILIB_USEDEP}]
  25. 	brotli? ( >=app-arch/brotli-1.0.6-r1:=[${MULTILIB_USEDEP}] )
  26. 	>=net-libs/libpsl-0.20[${MULTILIB_USEDEP}]
  27. 	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4[${MULTILIB_USEDEP}] )
  28. 	sys-libs/zlib
  29. 	gssapi? ( virtual/krb5[${MULTILIB_USEDEP}] )
  30. 	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
  31. 	samba? ( net-fs/samba )
  32. "
  33. RDEPEND="${DEPEND}
  34. 	>=net-libs/glib-networking-2.70_alpha[ssl?,${MULTILIB_USEDEP}]
  35. "
  36. BDEPEND="
  37. 	dev-libs/glib
  38. 	dev-util/glib-utils
  39. 	gtk-doc? ( >=dev-util/gtk-doc-1.20
  40. 		app-text/docbook-xml-dtd:4.1.2 )
  41. 	>=sys-devel/gettext-0.19.8
  42. 	virtual/pkgconfig
  43. 	vala? ( $(vala_depend) )
  44. 	test? ( >=net-libs/gnutls-3.6.0[pkcs11] )
  45. "
  46. #	test? (	www-servers/apache[ssl,apache2_modules_auth_digest,apache2_modules_alias,apache2_modules_auth_basic,
  47. #		apache2_modules_authn_file,apache2_modules_authz_host,apache2_modules_authz_user,apache2_modules_dir,
  48. #		apache2_modules_mime,apache2_modules_proxy,apache2_modules_proxy_http,apache2_modules_proxy_connect]
  49. #		dev-lang/php[apache2,xmlrpc]
  50. #		net-misc/curl
  51. #		net-libs/glib-networking[ssl])"
  53. PATCHES=(
  54. 	# Disable apache tests until they are usable on Gentoo, bug #326957
  55. 	"${FILESDIR}"/disable-apache-tests.patch
  56. )
  58. src_prepare() {
  59. 	default
  60. 	use vala && vala_setup
  61. 	xdg_environment_reset
  62. 	# https://gitlab.gnome.org/GNOME/libsoup/issues/159 - could work with libnss-myhostname
  63. 	sed -e '/hsts/d' -i tests/meson.build || die
  64. }
  66. src_configure() {
  67. 	# FIXME: we need addpredict to workaround bug #324779 until
  68. 	# root cause (bug #249496) is solved
  69. 	# But unnecessary while apache tests are disabled
  70. 	#addpredict /usr/share/snmp/mibs/.index
  72. 	multilib-minimal_src_configure
  73. }
  75. multilib_src_configure() {
  76. 	local emesonargs=(
  77. 		# Avoid auto-magic, built-in feature of meson
  78. 		-Dauto_features=enabled
  80. 		$(meson_feature gssapi)
  81. 		-Dkrb5_config="${CHOST}-krb5-config"
  82. 		$(meson_feature samba ntlm)
  83. 		$(meson_feature brotli)
  84. 		-Dntlm_auth="${EPREFIX}/usr/bin/ntlm_auth"
  85. 		-Dtls_check=false # disables check, we still rdep on glib-networking
  86. 		$(meson_native_use_feature introspection)
  87. 		$(meson_native_use_feature vala vapi)
  88. 		$(meson_native_use_bool gtk-doc gtk_doc)
  89. 		$(meson_use test tests)
  90. 		-Dinstalled_tests=false
  91. 		-Dhttp2_tests=disabled # quart is absent from gentoo repo
  92. 		-Dautobahn=disabled # autobahn depends on py-cryptography which depends on Rust
  93. 		$(meson_feature sysprof)
  94. 		$(meson_feature test pkcs11_tests)
  95. 	)
  96. 	meson_src_configure
  97. }