logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

libsoup-2.99.7.ebuild (2944B)

    

  1. # Copyright 1999-2021 Gentoo Authors

  2. # Distributed under the terms of the GNU General Public License v2

  3. 

  4. EAPI=7

  5. VALA_USE_DEPEND="vapigen"

  6. 

  7. inherit gnome.org meson-multilib vala xdg

  8. 

  9. DESCRIPTION="HTTP client/server library for GNOME"

  10. HOMEPAGE="https://wiki.gnome.org/Projects/libsoup"

  11. 

  12. LICENSE="LGPL-2.1+"

  13. SLOT="3/3.0"

  14. 

  15. # TODO: Default enable brotli at some point? But in 2.70.0 not advertised to servers yet - https://gitlab.gnome.org/GNOME/libsoup/issues/146

  16. IUSE="brotli gssapi gtk-doc +introspection samba ssl sysprof test +vala"

  17. RESTRICT="!test? ( test )"

  18. REQUIRED_USE="vala? ( introspection )"

  19. 

  20. KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"

  21. 

  22. DEPEND="

  23. 	>=dev-libs/glib-2.67:2[${MULTILIB_USEDEP}]

  24. 	>=dev-db/sqlite-3.8.2:3[${MULTILIB_USEDEP}]

  25. 	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]

  26. 	brotli? ( >=app-arch/brotli-1.0.6-r1:=[${MULTILIB_USEDEP}] )

  27. 	>=net-libs/libpsl-0.20[${MULTILIB_USEDEP}]

  28. 	sysprof? ( >=dev-util/sysprof-capture-3.40.1:4[${MULTILIB_USEDEP}] )

  29. 	sys-libs/zlib

  30. 	gssapi? ( virtual/krb5[${MULTILIB_USEDEP}] )

  31. 	introspection? ( >=dev-libs/gobject-introspection-1.54:= )

  32. 	samba? ( net-fs/samba )

  33. "

  34. RDEPEND="${DEPEND}

  35. 	>=net-libs/glib-networking-2.38.2[ssl?,${MULTILIB_USEDEP}]

  36. "

  37. BDEPEND="

  38. 	dev-libs/glib

  39. 	dev-util/glib-utils

  40. 	gtk-doc? ( >=dev-util/gtk-doc-1.20

  41. 		app-text/docbook-xml-dtd:4.1.2 )

  42. 	>=sys-devel/gettext-0.19.8

  43. 	virtual/pkgconfig

  44. 	vala? ( $(vala_depend) )

  45. "

  46. #	test? (	www-servers/apache[ssl,apache2_modules_auth_digest,apache2_modules_alias,apache2_modules_auth_basic,

  47. #		apache2_modules_authn_file,apache2_modules_authz_host,apache2_modules_authz_user,apache2_modules_dir,

  48. #		apache2_modules_mime,apache2_modules_proxy,apache2_modules_proxy_http,apache2_modules_proxy_connect]

  49. #		dev-lang/php[apache2,xmlrpc]

  50. #		net-misc/curl

  51. #		net-libs/glib-networking[ssl])"

  52. 

  53. PATCHES=(

  54. 	# Disable apache tests until they are usable on Gentoo, bug #326957

  55. 	"${FILESDIR}"/disable-apache-tests.patch

  56. )

  57. 

  58. src_prepare() {

  59. 	use vala && vala_src_prepare

  60. 	xdg_src_prepare

  61. 	# https://gitlab.gnome.org/GNOME/libsoup/issues/159 - could work with libnss-myhostname

  62. 	sed -e '/hsts/d' -i tests/meson.build || die

  63. }

  64. 

  65. src_configure() {

  66. 	# FIXME: we need addpredict to workaround bug #324779 until

  67. 	# root cause (bug #249496) is solved

  68. 	# But necessary while apache tests are disabled

  69. 	#addpredict /usr/share/snmp/mibs/.index

  70. 

  71. 	multilib-minimal_src_configure

  72. }

  73. 

  74. multilib_src_configure() {

  75. 	local emesonargs=(

  76. 		$(meson_feature gssapi)

  77. 		-Dkrb5_config="${CHOST}-krb5-config"

  78. 		$(meson_feature samba ntlm)

  79. 		$(meson_feature brotli)

  80. 		-Dntlm_auth="${EPREFIX}/usr/bin/ntlm_auth"

  81. 		-Dtls_check=false # disables check, we still rdep on glib-networking

  82. 		-Dgnome=false

  83. 		$(meson_native_use_feature introspection)

  84. 		$(meson_native_use_feature vala vapi)

  85. 		$(meson_native_use_bool gtk-doc gtk_doc)

  86. 		$(meson_use test tests)

  87. 		-Dinstalled_tests=false

  88. 		$(meson_feature sysprof)

  89. 	)

  90. 	meson_src_configure

  91. }