libsoup-2.68.3.ebuild (2610B)
1 # Copyright 1999-2019 Gentoo Authors
2 # Distributed under the terms of the GNU General Public License v2
3
4 EAPI=7
5 VALA_USE_DEPEND="vapigen"
6
7 inherit gnome.org meson multilib-minimal vala xdg
8
9 DESCRIPTION="HTTP client/server library for GNOME"
10 HOMEPAGE="https://wiki.gnome.org/Projects/libsoup"
11
12 LICENSE="LGPL-2.1+"
13 SLOT="2.4"
14
15 IUSE="+brotli gssapi gtk-doc +introspection samba ssl test +vala"
16 REQUIRED_USE="vala? ( introspection )"
17
18 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
19
20 DEPEND="
21 >=dev-libs/glib-2.58:2[${MULTILIB_USEDEP}]
22 >=dev-db/sqlite-3.8.2:3[${MULTILIB_USEDEP}]
23 >=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
24 >=net-libs/libpsl-0.20[${MULTILIB_USEDEP}]
25 brotli? ( app-arch/brotli:=[${MULTILIB_USEDEP}] )
26 gssapi? ( virtual/krb5[${MULTILIB_USEDEP}] )
27 introspection? ( >=dev-libs/gobject-introspection-1.54:= )
28 samba? ( net-fs/samba )
29 "
30 RDEPEND="${DEPEND}
31 >=net-libs/glib-networking-2.38.2[ssl?,${MULTILIB_USEDEP}]
32 "
33 BDEPEND="
34 dev-util/glib-utils
35 gtk-doc? ( >=dev-util/gtk-doc-1.20
36 app-text/docbook-xml-dtd:4.1.2 )
37 >=sys-devel/gettext-0.19.8
38 >=virtual/pkgconfig-0-r1[${MULTILIB_USEDEP}]
39 vala? ( $(vala_depend) )
40 "
41 # test? ( www-servers/apache[ssl,apache2_modules_auth_digest,apache2_modules_alias,apache2_modules_auth_basic,
42 # apache2_modules_authn_file,apache2_modules_authz_host,apache2_modules_authz_user,apache2_modules_dir,
43 # apache2_modules_mime,apache2_modules_proxy,apache2_modules_proxy_http,apache2_modules_proxy_connect]
44 # dev-lang/php[apache2,xmlrpc]
45 # net-misc/curl
46 # net-libs/glib-networking[ssl])"
47
48 PATCHES=(
49 # Disable apache tests until they are usable on Gentoo, bug #326957
50 "${FILESDIR}"/disable-apache-tests.patch
51 )
52
53 src_prepare() {
54 use vala && vala_src_prepare
55 xdg_src_prepare
56 }
57
58 src_configure() {
59 # FIXME: we need addpredict to workaround bug #324779 until
60 # root cause (bug #249496) is solved
61 # But necessary while apache tests are disabled
62 #addpredict /usr/share/snmp/mibs/.index
63
64 multilib-minimal_src_configure
65 }
66
67 multilib_src_configure() {
68 local emesonargs=(
69 $(meson_feature gssapi)
70 -Dkrb5_config="${CHOST}-krb5-config"
71 $(meson_feature samba ntlm)
72 -Dntlm_auth="${EPREFIX}/usr/bin/ntlm_auth"
73 $(meson_feature brotli)
74 -Dgnome=false
75 -Dintrospection=$(multilib_native_usex introspection enabled disabled)
76 -Dvapi=$(multilib_native_usex vala enabled disabled)
77 -Dgtk_doc=$(multilib_native_usex gtk-doc true false)
78 $(meson_use test tests)
79 )
80 meson_src_configure
81 }
82
83 multilib_src_compile() {
84 meson_src_compile
85 }
86
87 multilib_src_test() {
88 meson_src_test
89 }
90
91 multilib_src_install() {
92 meson_src_install
93 }