logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

glib-networking-2.72.0.ebuild (1969B)

    

  1. # Copyright 1999-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit gnome.org gnome2-utils meson-multilib xdg
  8. DESCRIPTION="Network-related giomodules for glib"
  9. HOMEPAGE="https://gitlab.gnome.org/GNOME/glib-networking"
  11. LICENSE="LGPL-2.1+"
  12. SLOT="0"
  13. IUSE="gnome +gnutls +libproxy openssl test +ssl"
  14. RESTRICT="!test? ( test )"
  15. KEYWORDS="~amd64"
  17. REQUIRED_USE="ssl? ( || ( gnutls openssl ) )"
  19. RDEPEND="
  20. 	>=dev-libs/glib-2.69.0:2[${MULTILIB_USEDEP}]
  21. 	libproxy? ( >=net-libs/libproxy-0.4.11-r1:=[${MULTILIB_USEDEP}] )
  22. 	gnutls? ( >=net-libs/gnutls-3.7.2:=[${MULTILIB_USEDEP}] )
  23. 	ssl? ( app-misc/ca-certificates )
  24. 	openssl? ( dev-libs/openssl:0=[${MULTILIB_USEDEP}] )
  25. 	gnome? ( gnome-base/gsettings-desktop-schemas )
  26. "
  28. DEPEND="${RDEPEND}
  29. 	test? ( net-libs/gnutls[pkcs11] )
  30. "
  31. BDEPEND="
  32. 	>=sys-devel/gettext-0.19.8
  33. 	virtual/pkgconfig
  34. 	test? ( sys-apps/dbus )
  35. "
  37. src_prepare() {
  38. 	default
  39. 	xdg_environment_reset
  41. 	if ! use test ; then
  42. 		# Don't build tests unconditionally
  43. 		# This is a hack to avoid needing gnutls[pkcs11] when USE=-test
  44. 		# It may become a real runtime dependency in future
  45. 		# Please check!
  46. 		# bug #777462
  47. 		sed -i "/^subdir('tests')/d" tls/meson.build || die
  48. 	fi
  49. }
  51. multilib_src_configure() {
  52. 	local emesonargs=(
  53. 		$(meson_feature gnutls)
  54. 		$(meson_feature openssl)
  55. 		$(meson_feature libproxy)
  56. 		$(meson_feature gnome gnome_proxy)
  57. 		-Dinstalled_tests=false
  58. 		-Dstatic_modules=false
  59. 	)
  61. 	meson_src_configure
  62. }
  64. multilib_src_test() {
  65. 	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
  66. }
  68. pkg_postinst() {
  69. 	xdg_pkg_postinst
  71. 	multilib_pkg_postinst() {
  72. 		gnome2_giomodule_cache_update \
  73. 			|| die "Update GIO modules cache failed (for ${ABI})"
  74. 	}
  75. 	multilib_foreach_abi multilib_pkg_postinst
  76. }
  78. pkg_postrm() {
  79. 	xdg_pkg_postrm
  81. 	multilib_pkg_postrm() {
  82. 		gnome2_giomodule_cache_update \
  83. 			|| die "Update GIO modules cache failed (for ${ABI})"
  84. 	}
  85. 	multilib_foreach_abi multilib_pkg_postrm
  86. }