logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

ldns-utils-1.7.0-r1.ebuild (1272B)

    

  1. # Copyright 1999-2019 Gentoo Authors

  2. # Distributed under the terms of the GNU General Public License v2

  3. 

  4. EAPI=6

  5. 

  6. MY_P=${P/-utils}

  7. 

  8. DESCRIPTION="Set of utilities to simplify various dns(sec) tasks"

  9. HOMEPAGE="https://www.nlnetlabs.nl/projects/ldns/"

  10. SRC_URI="https://www.nlnetlabs.nl/downloads/ldns/${MY_P}.tar.gz"

  11. 

  12. LICENSE="BSD"

  13. SLOT="0"

  14. KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390  ~sparc ~x86"

  15. IUSE="+dane ecdsa examples gost ssl"

  16. 

  17. REQUIRED_USE="

  18. 	ecdsa? ( ssl )

  19. 	dane? ( ssl )

  20. 	gost? ( ssl )

  21. "

  22. 

  23. DEPEND=">=net-libs/ldns-${PV}[dane?,ecdsa?,gost?]

  24. 	examples? ( net-libs/libpcap )"

  25. RDEPEND="${DEPEND}"

  26. 

  27. S=${WORKDIR}/${MY_P}

  28. 

  29. PATCHES=( "${FILESDIR}/${P}_libressl.patch" )

  30. 

  31. src_configure() {

  32. 	cd "${S}"/drill || die

  33. 	econf $(use_with ssl)

  34. 

  35. 	if use examples; then

  36. 		cd "${S}"/examples || die

  37. 		econf \

  38. 			$(use_enable dane) \

  39. 			$(use_enable ecdsa) \

  40. 			$(use_enable gost) \

  41. 			$(use_enable ssl sha2) \

  42. 			$(use_with ssl)

  43. 	fi

  44. }

  45. 

  46. src_compile() {

  47. 	emake -C drill

  48. 	if use examples; then

  49. 		emake -C examples

  50. 	fi

  51. }

  52. 

  53. src_install() {

  54. 	cd "${S}"/drill || die

  55. 	emake DESTDIR="${D}" install

  56. 	dodoc ChangeLog.22-nov-2005 README REGRESSIONS

  57. 

  58. 	if use examples; then

  59. 		cd "${S}"/examples || die

  60. 		emake DESTDIR="${D}" install

  61. 		newdoc README README.examples

  62. 	fi

  63. }