logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://anongit.hacktivis.me/git/overlay.git/

asncounter-0.3.0.ebuild (1222B)

    

  1. # Copyright 2025 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. PYTHON_COMPAT=( python3_{12..14} )
  7. DISTUTILS_USE_PEP517=setuptools
  8. inherit distutils-r1 optfeature
  10. DESCRIPTION="Count hits per autonomous system number (ASN) and related network blocks"
  11. HOMEPAGE="https://gitlab.com/anarcat/asncounter"
  12. SRC_URI="https://gitlab.com/anarcat/asncounter/-/archive/${PV}/${P}.tar.gz"
  13. LICENSE="AGPL-3+"
  14. SLOT="0"
  15. KEYWORDS="~amd64"
  17. RDEPEND="
  18. 	dev-python/pyasn[${PYTHON_USEDEP}]
  19. "
  20. DEPEND="${RDEPEND}"
  21. BDEPEND="app-text/lowdown"
  23. distutils_enable_tests pytest
  25. src_prepare() {
  26. 	distutils-r1_src_prepare
  28. 	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
  29. }
  31. python_test() {
  32. 	epytest -k 'not test_prometheus_record'
  33. }
  35. src_install() {
  36. 	distutils-r1_src_install
  38. 	lowdown -o asncounter.1 -s -t man asncounter.1.md || die
  39. 	doman asncounter.1
  40. }
  42. pkg_postinst() {
  43. 	optfeature "To get a debugging socket" dev-python/manhole
  44. 	optfeature "To scrape packets directly without tcpdump (slower)" net-analyzer/scapy
  45. 	optfeature "To export Prometheus metrics" dev-python/prometheus-client
  46. 	optfeature "To aggregate network blocks in the REPL or manhole" dev-python/netaddr
  47. }