logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

obs-studio-9999.ebuild (3700B)

    

  1. # Copyright 1999-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
  7. LUA_COMPAT=( luajit )
  8. PYTHON_COMPAT=( python3_{7..9} )
  10. inherit cmake lua-single python-single-r1 xdg-utils
  12. if [[ ${PV} == *9999 ]]; then
  13. 	inherit git-r3
  14. 	EGIT_REPO_URI="https://github.com/lanodan/obs-studio.git"
  15. 	EGIT_BRANCH="wayland"
  16. 	EGIT_SUBMODULES=()
  17. fi
  19. DESCRIPTION="Software for Recording and Streaming Live Video Content (wayland branch)"
  20. HOMEPAGE="https://obsproject.com"
  22. LICENSE="GPL-2"
  23. SLOT="0"
  24. IUSE="+alsa decklink fdk imagemagick jack lua nvenc pipewire pulseaudio python speex +ssl truetype v4l vlc wayland X"
  25. REQUIRED_USE="
  26. 	lua? ( ${LUA_REQUIRED_USE} )
  27. 	python? ( ${PYTHON_REQUIRED_USE} )
  28. "
  30. BDEPEND="
  31. 	lua? ( dev-lang/swig )
  32. 	python? ( dev-lang/swig )
  33. "
  34. DEPEND="
  35. 	>=dev-libs/jansson-2.5
  36. 	dev-qt/qtcore:5
  37. 	dev-qt/qtdeclarative:5
  38. 	dev-qt/qtgui:5
  39. 	dev-qt/qtmultimedia:5
  40. 	dev-qt/qtnetwork:5
  41. 	dev-qt/qtquickcontrols:5
  42. 	dev-qt/qtsql:5
  43. 	dev-qt/qtsvg:5
  44. 	dev-qt/qtwidgets:5
  45. 	X? (
  46. 		dev-qt/qtx11extras:5
  47. 		x11-libs/libX11
  48. 		x11-libs/libXcomposite
  49. 		x11-libs/libXfixes
  50. 		x11-libs/libXinerama
  51. 		x11-libs/libXrandr
  52. 		x11-libs/libxcb
  53. 	)
  54. 	dev-qt/qtxml:5
  55. 	media-libs/x264:=
  56. 	media-video/ffmpeg:=[x264]
  57. 	net-misc/curl
  58. 	sys-libs/zlib
  59. 	virtual/udev
  60. 	alsa? ( media-libs/alsa-lib )
  61. 	fdk? ( media-libs/fdk-aac:= )
  62. 	imagemagick? ( media-gfx/imagemagick:= )
  63. 	jack? ( virtual/jack )
  64. 	lua? ( ${LUA_DEPS} )
  65. 	nvenc? ( >=media-video/ffmpeg-4[video_cards_nvidia] )
  66. 	pipewire? ( media-video/pipewire )
  67. 	pulseaudio? ( media-sound/pulseaudio )
  68. 	python? ( ${PYTHON_DEPS} )
  69. 	speex? ( media-libs/speexdsp )
  70. 	ssl? ( net-libs/mbedtls:= )
  71. 	truetype? (
  72. 		media-libs/fontconfig
  73. 		media-libs/freetype
  74. 	)
  75. 	v4l? ( media-libs/libv4l )
  76. 	vlc? ( media-video/vlc:= )
  77. "
  78. RDEPEND="${DEPEND}"
  80. pkg_setup() {
  81. 	use lua && lua-single_pkg_setup
  82. 	use python && python-single-r1_pkg_setup
  83. }
  85. src_configure() {
  86. 	local libdir=$(get_libdir)
  87. 	local mycmakeargs=(
  88. 		-DBUILD_BROWSER=no
  89. 		-DBUILD_VST=no
  90. 		-DENABLE_WAYLAND=$(usex wayland)
  91. 		-DENABLE_X11=$(usex X)
  92. 		-DDISABLE_ALSA=$(usex !alsa)
  93. 		-DDISABLE_DECKLINK=$(usex !decklink)
  94. 		-DDISABLE_FREETYPE=$(usex !truetype)
  95. 		-DDISABLE_JACK=$(usex !jack)
  96. 		-DDISABLE_LIBFDK=$(usex !fdk)
  97. 		-DENABLE_PIPEWIRE=$(usex pipewire)
  98. 		-DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
  99. 		-DDISABLE_SPEEXDSP=$(usex !speex)
  100. 		-DDISABLE_V4L2=$(usex !v4l)
  101. 		-DDISABLE_VLC=$(usex !vlc)
  102. 		-DLIBOBS_PREFER_IMAGEMAGICK=$(usex imagemagick)
  103. 		-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
  104. 		-DUNIX_STRUCTURE=1
  105. 		-DWITH_RTMPS=$(usex ssl)
  106. 	)
  108. 	if [ ${PV} != *9999 ]; then
  109. 		mycmakeargs+=(
  110. 			-DOBS_VERSION_OVERRIDE=${PV}
  111. 		)
  112. 	fi
  114. 	if use lua || use python; then
  115. 		mycmakeargs+=(
  116. 			-DDISABLE_LUA=$(usex !lua)
  117. 			-DDISABLE_PYTHON=$(usex !python)
  118. 			-DENABLE_SCRIPTING=yes
  119. 		)
  120. 	else
  121. 		mycmakeargs+=( -DENABLE_SCRIPTING=no )
  122. 	fi
  124. 	cmake_src_configure
  125. }
  127. src_install() {
  128. 	cmake_src_install
  129. 	#external plugins may need some things not installed by default, install them here
  130. 	insinto /usr/include/obs/UI/obs-frontend-api
  131. 	doins UI/obs-frontend-api/obs-frontend-api.h
  132. }
  134. pkg_postinst() {
  135. 	xdg_icon_cache_update
  137. 	if ! use alsa && ! use pulseaudio; then
  138. 		elog
  139. 		elog "For the audio capture features to be available,"
  140. 		elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
  141. 		elog "be enabled."
  142. 		elog
  143. 	fi
  145. 	if ! has_version "sys-apps/dbus"; then
  146. 		elog
  147. 		elog "The 'sys-apps/dbus' package is not installed, but"
  148. 		elog "could be used for disabling hibernating, screensaving,"
  149. 		elog "and sleeping.  Where it is not installed,"
  150. 		elog "'xdg-screensaver reset' is used instead"
  151. 		elog "(if 'x11-misc/xdg-utils' is installed)."
  152. 		elog
  153. 	fi
  154. }
  156. pkg_postrm() {
  157. 	xdg_icon_cache_update
  158. }