logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

tenacity-9999.ebuild (2245B)

    

  1. # Copyright 2021-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. WX_GTK_VER="3.1"
  7. PYTHON_COMPAT=( python3_{7..11} )
  9. inherit git-r3 cmake python-single-r1 wxwidgets xdg
  11. DESCRIPTION="easy-to-use, cross-platform multi-track audio editor/recorder"
  12. HOMEPAGE="https://tenacityaudio.org/"
  13. EGIT_REPO_URI="https://github.com/tenacityteam/tenacity.git"
  14. EGIT_SUBMODULES=()
  15. # GPL-2: Tenacity code
  16. # CC-BY-3.0: Tenacity Documentation
  17. # CC-BY-4.0: Audacity Logo
  18. # Nyquist: BSD-style license for ./lib-src/libnyquist
  19. # BSD: ./lib-src/libnyquist/xlisp
  20. LICENSE="GPL-2 CC-BY-3.0 CC-BY-4.0 Nyquist BSD"
  21. SLOT="0"
  23. IUSE="+midi id3tag mp3 ogg +vorbis +flac sbsms soundtouch ffmpeg +lv2 twolame +vst2 vamp"
  25. REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  27. # vst2 dep on GTK+3[X]: https://github.com/tenacityteam/tenacity/issues/614
  28. RDEPEND="
  29. 	${PYTHON_DEPS}
  30. 	virtual/opengl
  31. 	sys-libs/zlib:=
  32. 	dev-libs/expat
  33. 	media-sound/lame
  34. 	media-libs/libsndfile
  35. 	media-libs/soxr
  36. 	dev-db/sqlite:3
  37. 	dev-libs/glib:2
  38. 	x11-libs/gtk+:3
  39. 	x11-libs/wxGTK:${WX_GTK_VER}
  40. 	midi? (
  41. 		media-libs/portmidi:=
  42. 		media-libs/portsmf:=
  43. 	)
  44. 	id3tag? ( media-libs/libid3tag:= )
  45. 	mp3? ( media-libs/libmad )
  46. 	twolame? ( media-sound/twolame )
  47. 	ogg? ( media-libs/libogg )
  48. 	vorbis? ( media-libs/libvorbis )
  49. 	flac? ( media-libs/flac:=[cxx] )
  50. 	sbsms? ( media-libs/libsbsms )
  51. 	soundtouch? ( media-libs/libsoundtouch:= )
  52. 	ffmpeg? ( media-video/ffmpeg:= )
  53. 	lv2? (
  54. 		media-libs/lv2
  55. 		media-libs/lilv
  56. 		media-libs/suil
  57. 	)
  58. 	vamp? ( media-libs/vamp-plugin-sdk )
  59. 	vst2? ( x11-libs/gtk+:3[X] )
  60. "
  61. DEPEND="
  62. 	${RDEPEND}
  63. 	sys-devel/gettext
  64. 	app-text/scdoc
  65. "
  67. # src/CMakeLists.txt already installs README.md
  68. DOCS=()
  70. src_prepare() {
  71. 	cmake_src_prepare
  73. 	sed -i 's;${_DATADIR}/doc/${AUDACITY_NAME};${_DATADIR}/doc/${PF};' \
  74. 		src/CMakeLists.txt || die
  75. }
  77. src_configure() {
  78. 	setup-wxwidgets
  80. 	local mycmakeargs=(
  81. 		-DBUILD_MANPAGE=ON
  82. 		-DMIDI=$(usex midi)
  83. 		-DID3TAG=$(usex id3tag)
  84. 		-DMP3_DECODING=$(usex mp3)
  85. 		-DMP2_ENCODING=$(usex twolame)
  86. 		-DOGG=$(usex ogg)
  87. 		-DVORBIS=$(usex vorbis)
  88. 		-DFLAC=$(usex flac)
  89. 		-DSBSMS=$(usex sbsms)
  90. 		-DSOUNDTOUCH=$(usex soundtouch)
  91. 		-DFFMPEG=$(usex ffmpeg)
  92. 		-DVAMP=$(usex vamp)
  93. 		-DLV2=$(usex lv2)
  94. 		-DVST2=$(usex vst2)
  95. 	)
  97. 	cmake_src_configure
  98. }