logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://anongit.hacktivis.me/git/overlay.git/

glfw-2.7.9.ebuild (1216B)

    

  1. # Copyright 1999-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. inherit toolchain-funcs multilib-minimal
  8. DESCRIPTION="The Portable OpenGL FrameWork"
  9. HOMEPAGE="https://www.glfw.org/"
  10. SRC_URI="https://github.com/glfw/glfw-legacy/archive/${PV}.tar.gz -> ${P}.tar.gz"
  11. S="${WORKDIR}/glfw-legacy-${PV}"
  13. LICENSE="ZLIB"
  14. SLOT="2"
  15. KEYWORDS="~x86 ~amd64 ~arm ~arm64 ~hppa ~ppc64"
  16. IUSE=""
  18. RDEPEND="
  19. 	x11-libs/libxkbcommon[${MULTILIB_USEDEP}]
  20. 	virtual/opengl[${MULTILIB_USEDEP}]
  21. 	x11-libs/libX11[${MULTILIB_USEDEP}]
  22. 	x11-libs/libXcursor[${MULTILIB_USEDEP}]
  23. 	x11-libs/libXinerama[${MULTILIB_USEDEP}]
  24. 	x11-libs/libXrandr[${MULTILIB_USEDEP}]
  25. 	x11-libs/libXxf86vm[${MULTILIB_USEDEP}]
  26. "
  27. DEPEND="
  28. 	${RDEPEND}
  29. 	x11-libs/libXi[${MULTILIB_USEDEP}]
  30. "
  32. src_prepare() {
  33. 	sed -i 's;$(PREFIX)/;$(DESTDIR)$(PREFIX)/;' lib/x11/Makefile.x11.in || die
  35. 	default
  37. 	multilib_copy_sources
  38. }
  40. multilib_src_configure() {
  41. 	sed -i 's;$(PREFIX)/lib;$(PREFIX)/'"$(get_libdir);" lib/x11/Makefile.x11.in || die
  43. 	sh "${S}/compile.sh" || die
  44. }
  46. multilib_src_compile() {
  47. 	export PREFIX="/usr"
  49. 	emake x11 AR="$(tc-getAR)"
  50. }
  52. multilib_src_install() {
  53. 	emake -j1 DESTDIR="${ED}" x11-install x11-dist-install
  54. }