logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

glew-2.1.0.ebuild (2394B)

    

  1. # Copyright 1999-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. inherit multilib-minimal toolchain-funcs
  8. DESCRIPTION="The OpenGL Extension Wrangler Library"
  9. HOMEPAGE="http://glew.sourceforge.net/"
  10. SRC_URI="mirror://sourceforge/${PN}/${P}.tgz"
  12. LICENSE="BSD MIT"
  13. SLOT="$(ver_cut 1-2)"
  14. KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  15. IUSE="doc static-libs"
  17. DEPEND="
  18. 	>=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
  19. 	>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
  20. 	>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
  21. 	>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
  22. 	>=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
  23. 	>=x11-libs/libXmu-1.1.1-r1[${MULTILIB_USEDEP}]
  24. "
  25. RDEPEND="${DEPEND}"
  27. src_prepare() {
  28. 	local PATCHES=(
  29. 		"${FILESDIR}"/${PN}-2.0.0-install-headers.patch
  30. 	)
  32. 	sed -i \
  33. 		-e '/INSTALL/s:-s::' \
  34. 		-e '/$(CC) $(CFLAGS) -o/s:$(CFLAGS):$(CFLAGS) $(LDFLAGS):' \
  35. 		-e '/^.PHONY: .*\.pc$/d' \
  36. 		Makefile || die
  38. 	if ! use static-libs ; then
  39. 		sed -i \
  40. 			-e '/glew.lib:/s|lib/$(LIB.STATIC) ||' \
  41. 			-e '/glew.lib.mx:/s|lib/$(LIB.STATIC.MX) ||' \
  42. 			-e '/INSTALL.*LIB.STATIC/d' \
  43. 			Makefile || die
  44. 	fi
  46. 	# don't do stupid Solaris specific stuff that won't work in Prefix
  47. 	cp config/Makefile.linux config/Makefile.solaris || die
  48. 	# and let freebsd be built as on linux too
  49. 	cp config/Makefile.linux config/Makefile.freebsd || die
  51. 	default
  52. 	multilib_copy_sources
  53. }
  55. glew_system() {
  56. 	# Set the SYSTEM variable instead of probing. #523444 #595280
  57. 	case ${CHOST} in
  58. 	*linux*)          echo "linux" ;;
  59. 	*-freebsd*)       echo "freebsd" ;;
  60. 	*-darwin*)        echo "darwin" ;;
  61. 	*-solaris*)       echo "solaris" ;;
  62. 	mingw*|*-mingw*)  echo "mingw" ;;
  63. 	*) die "Unknown system ${CHOST}" ;;
  64. 	esac
  65. }
  67. set_opts() {
  68. 	myglewopts=(
  69. 		AR="$(tc-getAR)"
  70. 		STRIP=true
  71. 		CC="$(tc-getCC)"
  72. 		LD="$(tc-getCC) ${LDFLAGS}"
  73. 		SYSTEM="$(glew_system)"
  74. 		M_ARCH=""
  75. 		LDFLAGS.EXTRA=""
  76. 		POPT="${CFLAGS}"
  77. 	)
  78. }
  80. multilib_src_compile() {
  81. 	set_opts
  82. 	emake \
  83. 		GLEW_PREFIX="${EPREFIX}/usr" \
  84. 		GLEW_DEST="${EPREFIX}/usr" \
  85. 		LIBDIR="${EPREFIX}/usr/$(get_libdir)" \
  86. 		glew.lib \
  87. 		"${myglewopts[@]}"
  88. }
  90. multilib_src_install() {
  91. 	set_opts
  92. 	emake \
  93. 		GLEW_DEST="${ED}/usr" \
  94. 		LIBDIR="${ED}/usr/$(get_libdir)" \
  95. 		PKGDIR="${ED}/usr/$(get_libdir)/pkgconfig" \
  96. 		"${myglewopts[@]}" \
  97. 		install.lib
  98. }