logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

freeglut-3.4.0.ebuild (1651B)

    

  1. # Copyright 1999-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. CMAKE_ECLASS=cmake
  7. inherit cmake-multilib
  9. DESCRIPTION="A free OpenGL utility toolkit, the open-sourced alternative to the GLUT library"
  10. HOMEPAGE="http://freeglut.sourceforge.net/"
  11. SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  13. LICENSE="MIT"
  14. SLOT="0"
  15. KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  16. IUSE="debug static-libs wayland-only gles2-only"
  18. RDEPEND="
  19. 	!wayland-only? (
  20. 		>=virtual/glu-9.0-r1[${MULTILIB_USEDEP}]
  21. 		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
  22. 		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
  23. 		>=x11-libs/libXi-1.7.2[${MULTILIB_USEDEP}]
  24. 		>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
  25. 		>=x11-libs/libXxf86vm-1.1.3[${MULTILIB_USEDEP}]
  26. 	)
  27. 	wayland-only? (
  28. 		media-libs/mesa[egl(+),${MULTILIB_USEDEP}]
  29. 		dev-libs/wayland[${MULTILIB_USEDEP}]
  30. 		x11-libs/libxkbcommon[${MULTILIB_USEDEP}]
  31. 	)
  32. 	!gles2-only? ( >=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}] )
  33. 	gles2-only? ( media-libs/mesa[gles1,gles2,${MULTILIB_USEDEP}] )
  34. "
  35. DEPEND="${RDEPEND}
  36. 	!wayland-only? ( x11-base/xorg-proto )"
  37. BDEPEND="virtual/pkgconfig"
  39. PATCHES=(
  40. 	"${FILESDIR}"/${PN}-3.2.1-opengl-cmake.patch
  41. )
  43. src_configure() {
  44. 	local mycmakeargs=(
  45. 		"-DFREEGLUT_BUILD_DEMOS=OFF"
  46. 		"-DFREEGLUT_BUILD_STATIC_LIBS=$(usex static-libs ON OFF)"
  47. 		"-DFREEGLUT_WAYLAND=$(usex wayland-only ON OFF)"
  48. 		"-DFREEGLUT_GLES=$(usex gles2-only ON OFF)"
  49. 	)
  50. 	cmake-multilib_src_configure
  51. }
  53. multilib_src_install() {
  54. 	cmake_src_install
  55. 	cp "${ED}"/usr/$(get_libdir)/pkgconfig/{,free}glut.pc || die
  56. }