logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

unifont-13.0.05.ebuild (1220B)

    

  1. # Copyright 2003-2020 Gentoo Authors
  2. # Copyright 2019-2021 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
  3. # Distributed under the terms of the GNU General Public License v2
  5. EAPI=7
  7. inherit font toolchain-funcs
  9. DESCRIPTION="GNU Unifont - a Pan-Unicode X11 bitmap iso10646 font"
  10. HOMEPAGE="https://unifoundry.com/"
  11. SRC_URI="mirror://gnu/${PN}/${P}/${P}.tar.gz"
  13. LICENSE="GPL-2"
  14. SLOT="0"
  15. KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~s390  ~sparc ~x86 "
  16. IUSE="fontforge utils"
  18. DEPEND="
  19. 	fontforge? (
  20. 		app-text/bdf2psf
  21. 		dev-lang/perl
  22. 		dev-perl/GD[png(-)]
  23. 		media-gfx/fontforge
  24. 		x11-apps/bdftopcf
  25. 	)
  26. "
  27. RDEPEND="
  28. 	utils? (
  29. 		dev-lang/perl
  30. 		dev-perl/GD[png(-)]
  31. 	)
  32. "
  34. src_prepare() {
  35. 	sed -i -e 's/install -s/install/' src/Makefile || die
  36. 	default
  37. }
  39. src_compile() {
  40. 	buildargs=(
  41. 		BUILDFONT=$(usex fontforge 1 '')
  42. 		CC="$(tc-getCC)"
  43. 		CFLAGS="${CFLAGS}"
  44. 		INSTALL="${INSTALL-install}"
  45. 	)
  46. 	if use fontforge || use utils; then
  47. 		emake "${buildargs[@]}"
  48. 	fi
  49. }
  51. src_install() {
  52. 	local installargs=(
  53. 		COMPRESS=0
  54. 		DESTDIR="${ED}"
  55. 		PCFDEST="${ED}${FONTDIR}"
  56. 		TTFDEST="${ED}${FONTDIR}"
  57. 	)
  58. 	use utils || installargs+=( -C font )
  59. 	emake "${buildargs[@]}" "${installargs[@]}" install
  60. 	font_xfont_config
  61. 	font_fontconfig
  62. }