logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

sway-1.8_rc3.ebuild (2647B)

    

  1. # Copyright 1999-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit fcaps meson optfeature
  8. DESCRIPTION="i3-compatible Wayland window manager"
  9. HOMEPAGE="https://swaywm.org"
  11. if [[ ${PV} == 9999 ]]; then
  12. 	inherit git-r3
  13. 	EGIT_REPO_URI="https://github.com/swaywm/${PN}.git"
  14. else
  15. 	MY_PV=${PV/_rc/-rc}
  16. 	SRC_URI="https://github.com/swaywm/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
  17. 	KEYWORDS=""
  18. 	S="${WORKDIR}/${PN}-${MY_PV}"
  19. fi
  21. LICENSE="MIT"
  22. SLOT="0"
  23. IUSE="grimshot +man +swaybar +swaynag tray wallpapers X"
  25. DEPEND="
  26. 	>=dev-libs/json-c-0.13:0=
  27. 	>=dev-libs/libinput-1.6.0:0=
  28. 	sys-auth/seatd:=
  29. 	dev-libs/libpcre2
  30. 	>=dev-libs/wayland-1.20.0
  31. 	x11-libs/cairo
  32. 	x11-libs/libxkbcommon
  33. 	x11-libs/pango
  34. 	x11-libs/pixman
  35. 	media-libs/mesa[gles2,libglvnd(+)]
  36. 	swaybar? ( x11-libs/gdk-pixbuf:2 )
  37. 	tray? ( || (
  38. 		sys-apps/systemd
  39. 		sys-auth/elogind
  40. 		sys-libs/basu
  41. 	) )
  42. 	wallpapers? ( gui-apps/swaybg[gdk-pixbuf(+)] )
  43. 	X? ( x11-libs/libxcb:0= )
  44. "
  45. if [[ ${PV} == 9999 ]]; then
  46. 	DEPEND+="~gui-libs/wlroots-9999:=[X?]"
  47. else
  48. 	DEPEND+="
  49. 		>=gui-libs/wlroots-0.16:=[X?]
  50. 		<gui-libs/wlroots-0.17:=[X?]
  51. 	"
  52. fi
  53. RDEPEND="
  54. 	x11-misc/xkeyboard-config
  55. 	grimshot? (
  56. 		app-misc/jq
  57. 		gui-apps/grim
  58. 		gui-apps/slurp
  59. 		gui-apps/wl-clipboard
  60. 		x11-libs/libnotify
  61. 	)
  62. 	${DEPEND}
  63. "
  64. BDEPEND="
  65. 	>=dev-libs/wayland-protocols-1.24
  66. 	>=dev-util/meson-0.60.0
  67. 	virtual/pkgconfig
  68. "
  69. if [[ ${PV} == 9999 ]]; then
  70. 	BDEPEND+="man? ( ~app-text/scdoc-9999 )"
  71. else
  72. 	BDEPEND+="man? ( >=app-text/scdoc-1.9.3 )"
  73. fi
  74. REQUIRED_USE="tray? ( swaybar )"
  76. src_configure() {
  77. 	local emesonargs=(
  78. 		$(meson_feature man man-pages)
  79. 		$(meson_feature tray)
  80. 		$(meson_feature X xwayland)
  81. 		$(meson_feature swaybar gdk-pixbuf)
  82. 		$(meson_use swaynag)
  83. 		$(meson_use swaybar)
  84. 		$(meson_use wallpapers default-wallpaper)
  85. 		-Dfish-completions=true
  86. 		-Dzsh-completions=true
  87. 		-Dbash-completions=true
  88. 	)
  90. 	meson_src_configure
  91. }
  93. src_install() {
  94. 	meson_src_install
  96. 	if use grimshot; then
  97. 		doman contrib/grimshot.1
  98. 		dobin contrib/grimshot
  99. 	fi
  101. 	# For realtime
  102. 	fcaps cap_sys_nice usr/bin/sway
  103. }
  105. pkg_postinst() {
  106. 	optfeature_header "There are several packages that may be useful with sway:"
  107. 	optfeature "wallpaper utility" gui-apps/swaybg
  108. 	optfeature "idle management utility" gui-apps/swayidle
  109. 	optfeature "simple screen locker" gui-apps/swaylock
  110. 	optfeature "lightweight notification daemon" gui-apps/mako
  111. 	echo
  112. 	einfo "For a list of additional addons and tools usable with sway please"
  113. 	einfo "visit the offical wiki at:"
  114. 	einfo "https://github.com/swaywm/sway/wiki/Useful-add-ons-for-sway"
  115. 	einfo "Please note that some of them might not (yet) available on gentoo"
  116. }