logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

wlroots-0.15.0.ebuild (1685B)

    

  1. # Copyright 1999-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. inherit meson
  8. DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor"
  9. HOMEPAGE="https://gitlab.freedesktop.org/wlroots/wlroots"
  11. if [[ ${PV} == 9999 ]]; then
  12. 	EGIT_REPO_URI="https://gitlab.freedesktop.org/${PN}/${PN}.git"
  13. 	inherit git-r3
  14. 	SLOT="0/9999"
  15. else
  16. 	SRC_URI="https://gitlab.freedesktop.org/wlroots/wlroots/-/releases/${PV}/downloads/${P}.tar.gz"
  17. 	KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
  18. 	SLOT="0/15"
  19. fi
  21. LICENSE="MIT"
  22. IUSE="vulkan x11-backend X"
  24. DEPEND="
  25. 	>=dev-libs/libinput-1.14.0:0=
  26. 	>=dev-libs/wayland-1.20.0
  27. 	>=dev-libs/wayland-protocols-1.24
  28. 	media-libs/mesa[egl(+),gles2,gbm(+)]
  29. 	sys-auth/seatd:=
  30. 	virtual/libudev
  31. 	vulkan? (
  32. 		dev-util/glslang:0=
  33. 		dev-util/vulkan-headers:0=
  34. 		media-libs/vulkan-loader:0=
  35. 	)
  36. 	>=x11-libs/libdrm-2.4.109
  37. 	x11-libs/libxkbcommon
  38. 	x11-libs/pixman
  39. 	x11-backend? ( x11-libs/libxcb:0= )
  40. 	X? (
  41. 		x11-base/xwayland
  42. 		x11-libs/libxcb:0=
  43. 		x11-libs/xcb-util-image
  44. 		x11-libs/xcb-util-wm
  45. 	)
  46. "
  47. RDEPEND="
  48. 	${DEPEND}
  49. "
  50. BDEPEND="
  51. 	>=dev-libs/wayland-protocols-1.24
  52. 	>=dev-util/meson-0.60.0
  53. 	virtual/pkgconfig
  54. "
  56. src_configure() {
  57. 	# xcb-util-errors is not on Gentoo Repository (and upstream seems inactive?)
  58. 	local emesonargs=(
  59. 		"-Dxcb-errors=disabled"
  60. 		"-Dexamples=false"
  61. 		"-Dwerror=false"
  62. 		-Drenderers=$(usex vulkan 'gles2,vulkan' gles2)
  63. 		-Dxwayland=$(usex X enabled disabled)
  64. 		-Dbackends=drm,libinput$(usex x11-backend ',x11' '')
  65. 	)
  67. 	meson_src_configure
  68. }
  70. pkg_postinst() {
  71. 	elog "You must be in the input group to allow your compositor"
  72. 	elog "to access input devices via libinput."
  73. }