logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

cog-9999.ebuild (1523B)

    

  1. # Copyright 2021-2023 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit meson git-r3
  8. DESCRIPTION="Single Window Launcher for WPE WebKit"
  9. HOMEPAGE="https://github.com/Igalia/cog"
  10. EGIT_REPO_URI="https://github.com/Igalia/cog.git"
  11. LICENSE="MIT"
  12. SLOT="0"
  13. IUSE="+drm gtk4 headless wayland X"
  15. # note: cogcore_dep is ./core/
  16. cogplatformcommon_dep="media-libs/libepoxy"
  17. wpebackend_fdo_dep=">=gui-libs/wpebackend-fdo-1.8.0"
  19. DEPEND="
  20. 	net-libs/wpewebkit:1.1=[X?]
  21. 	net-libs/libsoup:3.0
  22. 	drm? (
  23. 		${cogplatformcommon_dep}
  24. 		${wpebackend_fdo_dep}
  25. 		>=x11-libs/libdrm-2.4.71
  26. 		dev-libs/libinput:=
  27. 		virtual/libudev:=
  28. 	)
  29. 	gtk4? (
  30. 		${cogplatformcommon_dep}
  31. 		${wpebackend_fdo_dep}
  32. 		gui-libs/gtk:4
  33. 	)
  34. 	headless? ( ${wpebackend_fdo_dep} )
  35. 	wayland? (
  36. 		${wpebackend_fdo_dep}
  37. 		x11-libs/cairo
  38. 		media-libs/mesa[egl(+)]
  39. 		dev-libs/wayland
  40. 		dev-libs/wayland-protocols
  41. 		x11-libs/libxkbcommon
  42. 	)
  43. 	X? (
  44. 		${wpebackend_fdo_dep}
  45. 		${cogplatformcommon_dep}
  46. 		media-libs/mesa[egl(+)]
  47. 		x11-libs/libxcb
  48. 		x11-libs/libxkbcommon[X]
  49. 		x11-libs/libX11
  50. 	)
  51. "
  52. RDEPEND="${DEPEND}"
  53. BDEPEND="
  54. 	dev-util/meson-format-array
  55. 	wayland? ( dev-util/wayland-scanner )
  56. "
  58. src_configure() {
  59. 	local platforms=(
  60. 		$(usev drm)
  61. 		$(usev headless)
  62. 		$(usev wayland)
  63. 		$(usev gtk4)
  64. 	)
  65. 	use X && platforms+=( 'x11' )
  67. 	local emesonargs=(
  68. 		-Dsoup2=disabled
  69. 		-Dplatforms="$(meson-format-array ${platforms[@]})"
  70. 		-Dwayland_weston_direct_display=false
  71. 		-Dwayland_weston_content_protection=false
  72. 	)
  74. 	meson_src_configure
  75. }