logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

librsvg-2.40.21.ebuild (2483B)

    

  1. # Copyright 1999-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  5. GNOME2_EAUTORECONF="yes"
  7. inherit gnome2 multilib-minimal vala
  9. DESCRIPTION="Scalable Vector Graphics (SVG) rendering library"
  10. HOMEPAGE="https://wiki.gnome.org/Projects/LibRsvg"
  12. LICENSE="LGPL-2+"
  13. SLOT="2"
  14. KEYWORDS="~alpha ~arm ~hppa ~ia64 ~loong ~mips ~ppc ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x64-solaris"
  16. IUSE="+introspection tools +vala"
  17. REQUIRED_USE="vala? ( introspection )"
  19. RDEPEND="
  20. 	>=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}]
  21. 	>=dev-libs/libcroco-0.6.8-r1[${MULTILIB_USEDEP}]
  22. 	>=dev-libs/libxml2-2.9.1-r4:2[${MULTILIB_USEDEP}]
  23. 	>=x11-libs/cairo-1.12.14-r4[${MULTILIB_USEDEP}]
  24. 	>=x11-libs/gdk-pixbuf-2.30.7:2[introspection?,${MULTILIB_USEDEP}]
  25. 	>=x11-libs/pango-1.38.0[${MULTILIB_USEDEP}]
  26. 	introspection? ( >=dev-libs/gobject-introspection-0.10.8:= )
  27. 	tools? ( >=x11-libs/gtk+-3.10.0:3 )
  28. "
  29. DEPEND="${RDEPEND}"
  30. BDEPEND="
  31. 	dev-libs/gobject-introspection-common
  32. 	dev-libs/vala-common
  33. 	dev-util/glib-utils
  34. 	>=dev-util/gtk-doc-am-1.13
  35. 	virtual/pkgconfig
  36. 	x11-libs/gdk-pixbuf
  37. 	vala? ( $(vala_depend) )
  38. "
  39. # >=gtk-doc-am-1.13, gobject-introspection-common, vala-common needed by eautoreconf
  41. RESTRICT="test" # Lots of issues due to freetype changes and more; ever since newer tests got backported into 2.40.19
  43. PATCHES=(
  44. 	# https://bugzilla.gnome.org/show_bug.cgi?id=653323
  45. 	"${FILESDIR}/${PN}-2.40.12-gtk-optional.patch"
  46. )
  48. src_prepare() {
  49. 	use vala && vala_src_prepare
  50. 	gnome2_src_prepare
  51. }
  53. multilib_src_configure() {
  54. 	local myconf=(
  55. 		--disable-static
  56. 		--disable-tools  # only useful for librsvg developers
  57. 		$(multilib_native_use_enable introspection)
  58. 		$(multilib_native_use_with tools gtk3)
  59. 		$(multilib_native_use_enable vala)
  60. 		--enable-pixbuf-loader
  61. 	)
  63. 	# -Bsymbolic is not supported by the Darwin toolchain
  64. 	[[ ${CHOST} == *-darwin* ]] && myconf+=( --disable-Bsymbolic )
  66. 	ECONF_SOURCE=${S} gnome2_src_configure "${myconf[@]}"
  68. 	if multilib_is_native_abi; then
  69. 		ln -s "${S}"/doc/html doc/html || die
  70. 	fi
  71. }
  73. multilib_src_compile() {
  74. 	# causes segfault if set, see bug #411765
  75. 	unset __GL_NO_DSO_FINALIZER
  76. 	gnome2_src_compile
  77. }
  79. multilib_src_install() {
  80. 	gnome2_src_install
  81. }
  83. pkg_postinst() {
  84. 	# causes segfault if set, see bug 375615
  85. 	unset __GL_NO_DSO_FINALIZER
  86. 	multilib_foreach_abi gnome2_pkg_postinst
  87. }
  89. pkg_postrm() {
  90. 	# causes segfault if set, see bug 375615
  91. 	unset __GL_NO_DSO_FINALIZER
  92. 	multilib_foreach_abi gnome2_pkg_postrm
  93. }