logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

gvfs-1.32.2.ebuild (3834B)

    

  1. # Copyright 1999-2018 Gentoo Authors

  2. # Distributed under the terms of the GNU General Public License v2

  3. 

  4. EAPI=6

  5. GNOME2_LA_PUNT="yes"

  6. GNOME2_EAUTORECONF="yes"

  7. 

  8. inherit gnome2 systemd

  9. 

  10. DESCRIPTION="Virtual filesystem implementation for gio"

  11. HOMEPAGE="https://wiki.gnome.org/Projects/gvfs"

  12. SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"

  13. 

  14. LICENSE="LGPL-2+"

  15. SLOT="0"

  16. 

  17. IUSE="afp archive bluray cdda elogind fuse google gnome-keyring gnome-online-accounts gphoto2 gtk +http ios mtp nfs policykit samba sftp systemd test +udev udisks zeroconf"

  18. REQUIRED_USE="

  19. 	cdda? ( udev )

  20. 	elogind? ( !systemd udisks )

  21. 	google? ( gnome-online-accounts )

  22. 	mtp? ( udev )

  23. 	udisks? ( udev )

  24. 	systemd? ( !elogind udisks )

  25. "

  26. KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64  ~sparc ~x86   ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"

  27. 

  28. RDEPEND="

  29. 	app-crypt/gcr:=

  30. 	>=dev-libs/glib-2.51:2

  31. 	dev-libs/libxml2:2

  32. 	sftp? ( net-misc/openssh )

  33. 	afp? ( >=dev-libs/libgcrypt-1.2.2:0= )

  34. 	archive? ( app-arch/libarchive:= )

  35. 	bluray? ( media-libs/libbluray:= )

  36. 	elogind? ( >=sys-auth/elogind-229:0= )

  37. 	fuse? ( >=sys-fs/fuse-2.8.0:0 )

  38. 	gnome-keyring? ( app-crypt/libsecret )

  39. 	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.7.1:= )

  40. 	google? (

  41. 		>=dev-libs/libgdata-0.17.7:=[crypt,gnome-online-accounts]

  42. 		>=net-libs/gnome-online-accounts-3.17.1:= )

  43. 	gphoto2? ( >=media-libs/libgphoto2-2.5.0:= )

  44. 	gtk? ( >=x11-libs/gtk+-3.0:3 )

  45. 	http? ( >=net-libs/libsoup-2.42:2.4 )

  46. 	ios? (

  47. 		>=app-pda/libimobiledevice-1.2:=

  48. 		>=app-pda/libplist-1:= )

  49. 	mtp? (

  50. 		>=dev-libs/libusb-1.0.21

  51. 		>=media-libs/libmtp-1.1.12 )

  52. 	nfs? ( >=net-fs/libnfs-1.9.8 )

  53. 	policykit? (

  54. 		sys-auth/polkit

  55. 		sys-libs/libcap )

  56. 	samba? ( >=net-fs/samba-4[client] )

  57. 	systemd? ( >=sys-apps/systemd-206:0= )

  58. 	udev? (

  59. 		cdda? ( dev-libs/libcdio-paranoia )

  60. 		>=virtual/libgudev-147:=

  61. 		virtual/libudev:= )

  62. 	udisks? ( >=sys-fs/udisks-1.97:2 )

  63. 	zeroconf? ( >=net-dns/avahi-0.6 )

  64. "

  65. DEPEND="${RDEPEND}

  66. 	app-text/docbook-xsl-stylesheets

  67. 	dev-libs/libxslt

  68. 	>=sys-devel/gettext-0.19.4

  69. 	virtual/pkgconfig

  70. 	dev-util/gdbus-codegen

  71. 	dev-util/glib-utils

  72. 	dev-util/gtk-doc-am

  73. 	test? (

  74. 		>=dev-python/twisted-16

  75. 		|| (

  76. 			net-analyzer/netcat

  77. 			net-analyzer/netcat6 ) )

  78. 	!udev? ( >=dev-libs/libgcrypt-1.2.2:0 )

  79. "

  80. # libgcrypt.m4, provided by libgcrypt, needed for eautoreconf, bug #399043

  81. # test dependencies needed per https://bugzilla.gnome.org/700162

  82. 

  83. # Tests with multiple failures, this is being handled upstream at:

  84. # https://bugzilla.gnome.org/700162

  85. RESTRICT="test"

  86. 

  87. PATCHES=(

  88. 	"${WORKDIR}"/patches/ #599482, 641522, gnome-3-24 backports

  89. 	"${FILESDIR}"/${PN}-1.30.2-sysmacros.patch #580234

  90. )

  91. 

  92. src_prepare() {

  93. 	if ! use udev; then

  94. 		sed -e 's/gvfsd-burn/ /' \

  95. 			-e 's/burn.mount.in/ /' \

  96. 			-e 's/burn.mount/ /' \

  97. 			-i daemon/Makefile.am || die

  98. 	fi

  99. 

  100. 	gnome2_src_prepare

  101. }

  102. 

  103. src_configure() {

  104. 	# --enable-documentation installs man pages

  105. 	# --disable-obexftp, upstream bug #729945

  106. 	gnome2_src_configure \

  107. 		--disable-gdu \

  108. 		--enable-documentation \

  109. 		--enable-gcr \

  110. 		--with-dbus-service-dir="${EPREFIX}"/usr/share/dbus-1/services \

  111. 		--with-systemduserunitdir="$(systemd_get_userunitdir)" \

  112. 		$(use_enable afp) \

  113. 		$(use_enable archive) \

  114. 		$(use_enable bluray) \

  115. 		$(use_enable cdda) \

  116. 		$(use_enable elogind libelogind) \

  117. 		$(use_enable fuse) \

  118. 		$(use_enable gnome-keyring keyring) \

  119. 		$(use_enable gnome-online-accounts goa) \

  120. 		$(use_enable google) \

  121. 		$(use_enable gphoto2) \

  122. 		$(use_enable gtk) \

  123. 		$(use_enable http) \

  124. 		$(use_enable ios afc) \

  125. 		$(use_enable mtp libmtp) \

  126. 		$(use_enable mtp libusb) \

  127. 		$(use_enable nfs) \

  128. 		$(use_enable policykit admin) \

  129. 		$(use_enable samba) \

  130. 		$(use_enable sftp) \

  131. 		$(use_enable systemd libsystemd-login) \

  132. 		$(use_enable udev gudev) \

  133. 		$(use_enable udev) \

  134. 		$(use_enable udisks udisks2) \

  135. 		$(use_enable zeroconf avahi)

  136. }