logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

solarus-1.6.5.ebuild (1193B)

    

  1. # Copyright 1999-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. LUA_COMPAT=( lua5-1 luajit )
  8. inherit cmake lua-single virtualx
  10. DESCRIPTION="An open-source Zelda-like 2D game engine"
  11. HOMEPAGE="https://www.solarus-games.org/"
  12. SRC_URI="https://gitlab.com/solarus-games/solarus/-/archive/v${PV}/solarus-v${PV}.tar.gz"
  13. S="${WORKDIR}/${PN}-v${PV}"
  15. LICENSE="GPL-3"
  16. SLOT="0"
  17. KEYWORDS="~amd64 ~x86"
  18. IUSE="doc qt5 test"
  19. RESTRICT="!test? ( test )"
  21. RDEPEND="
  22. 	${LUA_DEPS}
  23. 	dev-games/physfs
  24. 	media-libs/glm
  25. 	media-libs/libmodplug
  26. 	media-libs/libsdl2[X,joystick,video]
  27. 	media-libs/libvorbis
  28. 	media-libs/openal
  29. 	virtual/opengl
  30. 	media-libs/sdl2-image[png]
  31. 	media-libs/sdl2-ttf
  32. 	qt5? ( dev-qt/qtgui:5 )
  33. "
  34. DEPEND="
  35. 	${RDEPEND}
  36. 	doc? ( app-doc/doxygen )
  37. "
  39. src_prepare() {
  40. 	cmake_src_prepare
  41. }
  43. src_configure() {
  44. 	local mycmakeargs=(
  45. 		-DSOLARUS_USE_LUAJIT="$(usex lua_single_target_luajit)"
  46. 		-DSOLARUS_GUI="$(usex qt5)"
  47. 	)
  48. 	cmake_src_configure
  49. }
  51. src_compile() {
  52. 	cmake_src_compile
  53. 	if use doc ; then
  54. 		cd doc || die
  55. 		doxygen || die
  56. 	fi
  57. }
  59. src_test() {
  60. 	virtx cmake_src_test
  61. }
  63. src_install() {
  64. 	cmake_src_install
  65. 	use doc && dodoc -r doc/${PV%.*}/html/*
  66. }