logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

renpy-8.0.3-r1.ebuild (2614B)

    

  1. # Copyright 1999-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  5. PYTHON_COMPAT=( python3_{8,9,10} )
  6. DISTUTILS_SINGLE_IMPL=1
  7. DISTUTILS_USE_PEP517=setuptools
  8. inherit gnome2-utils distutils-r1
  10. DESCRIPTION="Visual novel engine written in python"
  11. HOMEPAGE="https://www.renpy.org"
  12. SRC_URI="https://www.renpy.org/dl/${PV}/${P}-source.tar.bz2"
  13. S="${WORKDIR}/${P}-source"
  15. LICENSE="MIT"
  16. SLOT=0
  17. KEYWORDS="~amd64"
  18. IUSE="development doc examples"
  19. REQUIRED_USE="examples? ( development )"
  21. BDEPEND="
  22. 	$(python_gen_cond_dep 'dev-python/cython[${PYTHON_USEDEP}]')
  23. 	virtual/pkgconfig"
  24. DEPEND="
  25. 	dev-libs/fribidi
  26. 	$(python_gen_cond_dep '
  27. 		'~dev-python/pygame_sdl2-${PV}'[${PYTHON_USEDEP}]
  28. 		>=dev-lang/python-exec-0.3[${PYTHON_USEDEP}]
  29. 	')
  30. 	media-libs/glew:0
  31. 	media-libs/libpng:0
  32. 	media-libs/libsdl2[video]
  33. 	media-libs/freetype:2
  34. 	sys-libs/zlib
  35. 	media-video/ffmpeg"
  36. RDEPEND="${DEPEND}
  37. 	!app-eselect/eselect-renpy"
  39. PATCHES=(
  40. 	"${FILESDIR}/${P}-system-path.patch"
  41. 	"${FILESDIR}/renpy-6.99.12.4-compat-style.patch"
  42. 	"${FILESDIR}/renpy-6.99.12.4-compat-infinite-loop.patch"
  43. 	"${FILESDIR}/${P}-use-system-fribidi.patch"
  44. 	"${FILESDIR}/renpy-8.0.3-ignore_rpyc_errors.patch"
  45. )
  47. python_prepare_all() {
  48. 	einfo "Deleting precompiled python files"
  49. 	find . -name '*.py[co]' -print -delete || die
  50. 	rm -r module/fribidi-src || die
  52. 	export CFLAGS="${CFLAGS} $($(tc-getPKG_CONFIG) --cflags fribidi)"
  53. 	distutils-r1_python_prepare_all
  54. }
  56. python_compile() {
  57. 	cd "${S}"/module || die
  58. 	distutils-r1_python_compile
  59. }
  61. python_install() {
  62. 	cd "${S}"/module || die
  63. 	distutils-r1_python_install
  65. 	cd "${S}" || die
  66. 	python_newscript renpy.py ${PN}
  68. 	python_domodule renpy
  69. 	if use development ; then
  70. 		python_domodule launcher
  71. 	fi
  72. 	if use examples ; then
  73. 		python_domodule the_question tutorial
  74. 	fi
  75. }
  77. python_install_all() {
  78. 	distutils-r1_python_install_all
  79. 	if use development; then
  80. 		newicon -s 32 launcher/game/images/logo32.png ${P}.png
  81. 		make_desktop_entry ${PN} "Ren'Py ${PV}" ${P}
  82. 	fi
  84. 	if use doc; then
  85. 		insinto "/usr/share/doc/${PF}/html"
  86. 		doins -r doc/*
  87. 	fi
  88. 	newman "${FILESDIR}/${PN}.1" "${P}.1"
  89. }
  91. pkg_preinst() {
  92. 	use development && gnome2_icon_savelist
  93. }
  95. pkg_postinst() {
  96. 	use development && gnome2_icon_cache_update
  98. 	local v
  99. 	for v in ${REPLACING_VERSIONS}; do
  100. 		ver_test "${v}" -ge 7 && continue
  101. 		einfo "Starting from ${PN}-7 slots are dropped."
  102. 		einfo "RenPy natively supports compatibility with games made for older versions."
  103. 		einfo "Report bugs upstream on such problems, usually they are easy to fix."
  104. 		break
  105. 	done
  106. }
  108. pkg_postrm() {
  109. 	use development && gnome2_icon_cache_update
  110. }