logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://anongit.hacktivis.me/git/overlay.git/

srb2-2.2.13.ebuild (1095B)

    

  1. # Copyright 2023 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. DESCRIPTION="3D Sonic fan game based off of Doom Legacy"
  7. HOMEPAGE="https://srb2.org"
  8. SRC_URI="
  9. 	https://github.com/STJr/SRB2/archive/refs/tags/SRB2_release_${PV}.tar.gz
  10. 	https://github.com/STJr/SRB2/releases/download/SRB2_release_${PV}/SRB2-v${PV//.}-Full.zip
  11. "
  12. S="${WORKDIR}/SRB2-SRB2_release_${PV}/"
  13. LICENSE="GPL-2"
  14. SLOT="0"
  15. KEYWORDS="~amd64"
  17. DEPEND="
  18. 	media-libs/game-music-emu
  19. 	media-libs/libopenmpt
  20. 	media-libs/libpng:=
  21. 	media-libs/libsdl2
  22. 	media-libs/sdl2-mixer
  23. 	net-misc/curl
  24. 	sys-libs/zlib
  25. "
  26. RDEPEND="${DEPEND}"
  28. PATCHES=(
  29. 	"${FILESDIR}/srb2-2.2.13-execinfo_guard.patch"
  30. )
  32. src_prepare() {
  33. 	default
  35. 	rm -r libs || die
  36. 	rm "${WORKDIR}"/*.dll "${WORKDIR}"/srb2win.exe || die
  38. 	# Don't strip executable
  39. 	sed -i 's;all : $(exe);all : $(dbg);' src/Makefile || die
  40. }
  42. src_compile() {
  43. 	emake -C src/ USE_OPENMP=1 DBGNAME=srb2
  44. }
  46. src_install() {
  47. 	dobin bin/srb2
  49. 	cd "${WORKDIR}" || die
  50. 	insinto /usr/share/games/SRB2
  51. 	doins models.dat *.dta *.pk3
  52. }