supertuxkart-1.0.ebuild (1802B)
1 # Copyright 1999-2018 Gentoo Foundation
2 # Distributed under the terms of the GNU General Public License v2
3
4 EAPI=6
5
6 inherit cmake-utils desktop gnome2-utils
7
8 DESCRIPTION="A kart racing game starring Tux, the linux penguin (TuxKart fork)"
9 HOMEPAGE="https://supertuxkart.net/"
10 SRC_URI="mirror://sourceforge/${PN}/SuperTuxKart/${PV}/${P}-src.tar.xz
11 mirror://gentoo/${PN}.png"
12
13 LICENSE="GPL-2 GPL-3 CC-BY-SA-3.0 CC-BY-2.0 public-domain ZLIB"
14 SLOT="0"
15 KEYWORDS="~amd64 ~x86"
16 IUSE="debug fribidi recorder wiimote"
17
18 # don't unbundle irrlicht and bullet
19 # both are modified and system versions will break the game
20 # https://sourceforge.net/p/irrlicht/feature-requests/138/
21
22 RDEPEND="
23 media-libs/glew:0=
24 media-libs/libpng:0=
25 media-libs/libvorbis
26 media-libs/openal
27 net-libs/enet:1.3=
28 net-misc/curl
29 sys-libs/zlib
30 virtual/glu
31 virtual/jpeg:0
32 virtual/libintl
33 virtual/opengl
34 x11-libs/libX11
35 x11-libs/libXxf86vm
36 fribidi? ( dev-libs/fribidi )
37 recorder? ( media-libs/libopenglrecorder )
38 wiimote? ( net-wireless/bluez )"
39 DEPEND="${RDEPEND}
40 sys-devel/gettext
41 virtual/pkgconfig"
42
43 PATCHES=(
44 )
45
46 src_prepare() {
47 cmake-utils_src_prepare
48
49 # remove bundled libraries, just to be sure
50 rm -r lib/{enet,glew,jpeglib,libpng,zlib} || die
51 }
52
53 src_configure() {
54 local mycmakeargs=(
55 # system dev-libs/angelscript leads
56 # to failed assert segfaults
57 -DUSE_SYSTEM_ANGELSCRIPT=OFF
58 -DUSE_FRIBIDI=$(usex fribidi)
59 -DBUILD_RECORDER=$(usex recorder)
60 -DUSE_WIIUSE=$(usex wiimote)
61 -DSTK_INSTALL_BINARY_DIR=bin
62 -DSTK_INSTALL_DATA_DIR=share/${PN}
63 )
64 cmake-utils_src_configure
65 }
66
67 src_install() {
68 cmake-utils_src_install
69 dodoc CHANGELOG.md
70
71 doicon -s 64 "${DISTDIR}"/${PN}.png
72 }
73
74 pkg_preinst() {
75 gnome2_icon_savelist
76 }
77
78 pkg_postinst() {
79 gnome2_icon_cache_update
80 }
81
82 pkg_postrm() {
83 gnome2_icon_cache_update
84 }