glib-utils-2.62.0.ebuild (2418B)
1 # Copyright 1999-2019 Gentoo Authors
2 # Distributed under the terms of the GNU General Public License v2
3
4 EAPI=6
5 PYTHON_COMPAT=( python{3_5,3_6,3_7} )
6 GNOME_ORG_MODULE="glib"
7
8 inherit gnome.org python-single-r1
9
10 DESCRIPTION="Build utilities for GLib using projects"
11 HOMEPAGE="https://www.gtk.org/"
12
13 LICENSE="LGPL-2.1+"
14 SLOT="0" # /usr/bin utilities that can't be parallel installed by their nature
15 IUSE=""
16 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
17
18 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris ~x86-winnt"
19
20 RDEPEND="${PYTHON_DEPS}
21 !<dev-libs/glib-2.56.2:2
22 "
23 DEPEND="${RDEPEND}
24 dev-libs/libxslt
25 app-text/docbook-xsl-stylesheets
26 "
27
28 src_configure() { :; }
29
30 do_xsltproc_command() {
31 # Taken from meson.build for manual manpage building - keep in sync (also copied to dev-util/gdbus-codegen)
32 xsltproc \
33 --nonet \
34 --stringparam man.output.quietly 1 \
35 --stringparam funcsynopsis.style ansi \
36 --stringparam man.th.extra1.suppress 1 \
37 --stringparam man.authors.section.enabled 0 \
38 --stringparam man.copyright.section.enabled 0 \
39 -o "${2}" \
40 http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl \
41 "${1}" || die "manpage generation failed"
42 }
43
44 src_compile() {
45 sed -e "s:@VERSION@:${PV}:g;s:@PYTHON@:python:g" gobject/glib-genmarshal.in > gobject/glib-genmarshal || die
46 sed -e "s:@VERSION@:${PV}:g;s:@PYTHON@:python:g" gobject/glib-mkenums.in > gobject/glib-mkenums || die
47 sed -e "s:@GLIB_VERSION@:${PV}:g;s:@PYTHON@:python:g" glib/gtester-report.in > glib/gtester-report || die
48 do_xsltproc_command docs/reference/gobject/glib-genmarshal.xml docs/reference/gobject/glib-genmarshal.1
49 do_xsltproc_command docs/reference/gobject/glib-mkenums.xml docs/reference/gobject/glib-mkenums.1
50 do_xsltproc_command docs/reference/glib/gtester-report.xml docs/reference/glib/gtester-report.1
51 }
52
53 src_install() {
54 python_fix_shebang gobject/glib-genmarshal
55 python_fix_shebang gobject/glib-mkenums
56 python_fix_shebang glib/gtester-report
57 exeinto /usr/bin
58 doexe gobject/glib-genmarshal
59 doexe gobject/glib-mkenums
60 doexe glib/gtester-report
61 doman docs/reference/gobject/glib-genmarshal.1
62 doman docs/reference/gobject/glib-mkenums.1
63 doman docs/reference/glib/gtester-report.1
64 }