libdazzle-3.33.1.ebuild (1342B)
1 # Copyright 1999-2019 Gentoo Authors
2 # Distributed under the terms of the GNU General Public License v2
3
4 EAPI=6
5
6 inherit gnome.org meson xdg vala virtualx
7
8 DESCRIPTION="Experimental new features for GTK+ and GLib"
9 HOMEPAGE="https://gitlab.gnome.org/GNOME/libdazzle"
10
11 LICENSE="GPL-3+"
12 SLOT="0"
13 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
14
15 IUSE="gtk-doc +introspection test vala"
16 REQUIRED_USE="vala? ( introspection )"
17 RESTRICT="!test? ( test )"
18
19 RDEPEND="
20 >=dev-libs/glib-2.56.0:2
21 >=x11-libs/gtk+-3.24.0:3[introspection?]
22 introspection? ( dev-libs/gobject-introspection:= )
23 "
24 # libxml2 required for glib-compile-resources; glib-utils for glib-mkenums
25 DEPEND="${RDEPEND}
26 vala? ( $(vala_depend) )
27 dev-libs/libxml2:2
28 dev-util/glib-utils
29 virtual/pkgconfig
30 gtk-doc? ( dev-util/gtk-doc )
31 "
32
33 src_prepare() {
34 use vala && vala_src_prepare
35 xdg_src_prepare
36 }
37
38 src_configure() {
39 local emesonargs=(
40 -Denable_tracing=false # extra trace debugging that would make things slower
41 -Denable_profiling=false # -pg passing
42 # -Denable_rdtscp=false # TODO: CPU_FLAGS_X86 for it?
43 -Denable_tools=true # /usr/bin/dazzle-list-counters
44 $(meson_use introspection with_introspection)
45 $(meson_use vala with_vapi)
46 $(meson_use gtk-doc enable_gtk_doc)
47 $(meson_use test enable_tests)
48 )
49 meson_src_configure
50 }
51
52 src_test() {
53 virtx meson_src_test
54 }