logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

elfutils-0.186_pre9999.ebuild (2195B)

    

  1. # Copyright 2003-2021 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=7
  6. inherit flag-o-matic multilib-minimal autotools git-r3
  8. DESCRIPTION="Libraries/utilities to handle ELF objects (drop in replacement for libelf)"
  9. HOMEPAGE="http://elfutils.org/"
  10. EGIT_REPO_URI="git://sourceware.org/git/elfutils.git"
  12. LICENSE="|| ( GPL-2+ LGPL-3+ ) utils? ( GPL-3+ )"
  13. SLOT="0"
  14. IUSE="bzip2 lzma nls static-libs test +threads +utils valgrind zstd"
  16. RDEPEND=">=sys-libs/zlib-1.2.8-r1[static-libs?,${MULTILIB_USEDEP}]
  17. 	bzip2? ( >=app-arch/bzip2-1.0.6-r4[static-libs?,${MULTILIB_USEDEP}] )
  18. 	lzma? ( >=app-arch/xz-utils-5.0.5-r1[static-libs?,${MULTILIB_USEDEP}] )
  19. 	zstd? ( app-arch/zstd:=[static-libs?,${MULTILIB_USEDEP}] )
  20. 	!dev-libs/libelf
  21. "
  22. DEPEND="${RDEPEND}
  23. 	valgrind? ( dev-util/valgrind )
  24. "
  25. BDEPEND="nls? ( sys-devel/gettext )
  26. 	>=sys-devel/flex-2.5.4a
  27. 	sys-devel/m4
  28. "
  29. RESTRICT="!test? ( test )"
  31. PATCHES=(
  32. 	"${FILESDIR}"/${PN}-0.186-gnu99-cleanup.patch
  33. )
  35. src_prepare() {
  36. 	default
  37. 	eautoreconf
  39. 	if ! use static-libs; then
  40. 		sed -i -e '/^lib_LIBRARIES/s:=.*:=:' -e '/^%.os/s:%.o$::' lib{asm,dw,elf}/Makefile.in || die
  41. 	fi
  42. 	# https://sourceware.org/PR23914
  43. 	sed -i 's:-Werror::' */Makefile.in || die
  44. }
  46. src_configure() {
  47. 	use test && append-flags -g #407135
  49. 	# Symbol aliases are implemented as asm statements.
  50. 	# Will require porting: https://gcc.gnu.org/PR48200
  51. 	filter-flags '-flto*'
  53. 	multilib-minimal_src_configure
  54. }
  56. multilib_src_configure() {
  57. 	ECONF_SOURCE="${S}" econf \
  58. 		$(use_enable nls) \
  59. 		$(use_enable threads thread-safety) \
  60. 		$(use_enable valgrind) \
  61. 		--disable-debuginfod \
  62. 		--disable-libdebuginfod \
  63. 		--program-prefix="eu-" \
  64. 		--with-zlib \
  65. 		--enable-maintainer-mode \
  66. 		$(use_with bzip2 bzlib) \
  67. 		$(use_with lzma) \
  68. 		$(use_with zstd)
  69. }
  71. multilib_src_test() {
  72. 	env	LD_LIBRARY_PATH="${BUILD_DIR}/libelf:${BUILD_DIR}/libebl:${BUILD_DIR}/libdw:${BUILD_DIR}/libasm" \
  73. 		LC_ALL="C" \
  74. 		emake check VERBOSE=1
  75. }
  77. multilib_src_install_all() {
  78. 	einstalldocs
  79. 	dodoc NOTES
  80. 	# These build quick, and are needed for most tests, so don't
  81. 	# disable their building when the USE flag is disabled.
  82. 	if ! use utils; then
  83. 		rm -rf "${ED}"/usr/bin || die
  84. 	fi
  85. }