logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

evince-3.34.2.ebuild (3151B)

    

  1. # Copyright 1999-2019 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=6
  5. GNOME2_LA_PUNT="yes"
  6. GNOME2_EAUTORECONF="yes"
  8. inherit gnome2 systemd
  10. DESCRIPTION="Simple document viewer for GNOME"
  11. HOMEPAGE="https://wiki.gnome.org/Apps/Evince"
  13. LICENSE="GPL-2+ CC-BY-SA-3.0"
  14. # subslot = evd3.(suffix of libevdocument3)-evv3.(suffix of libevview3)
  15. SLOT="0/evd3.4-evv3.3"
  16. IUSE="dbus djvu dvi gstreamer gnome gnome-keyring +introspection nautilus nsplugin postscript spell t1lib tiff xps"
  17. KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86  ~amd64-linux ~x86-linux ~x64-solaris"
  19. # atk used in libview
  20. # bundles unarr
  21. COMMON_DEPEND="
  22. 	dev-libs/atk
  23. 	>=dev-libs/glib-2.36:2[dbus?]
  24. 	>=dev-libs/libxml2-2.5:2
  25. 	sys-libs/zlib:=
  26. 	>=x11-libs/gdk-pixbuf-2.36.5:2
  27. 	>=x11-libs/gtk+-3.22.0:3[introspection?]
  28. 	gnome-base/gsettings-desktop-schemas
  29. 	>=x11-libs/cairo-1.10:=
  30. 	>=app-text/poppler-0.33[cairo]
  31. 	>=app-arch/libarchive-3.2.0
  32. 	djvu? ( >=app-text/djvu-3.5.22:= )
  33. 	dvi? (
  34. 		virtual/tex-base
  35. 		dev-libs/kpathsea:=
  36. 		t1lib? ( >=media-libs/t1lib-5:= ) )
  37. 	gstreamer? (
  38. 		media-libs/gstreamer:1.0
  39. 		media-libs/gst-plugins-base:1.0
  40. 		media-libs/gst-plugins-good:1.0 )
  41. 	gnome? ( gnome-base/gnome-desktop:3= )
  42. 	gnome-keyring? ( >=app-crypt/libsecret-0.5 )
  43. 	introspection? ( >=dev-libs/gobject-introspection-1:= )
  44. 	nautilus? ( >=gnome-base/nautilus-2.91.4 )
  45. 	postscript? ( >=app-text/libspectre-0.2:= )
  46. 	spell? ( >=app-text/gspell-1.6.0:= )
  47. 	tiff? ( >=media-libs/tiff-3.6:0= )
  48. 	xps? ( >=app-text/libgxps-0.2.1:= )
  49. "
  50. RDEPEND="${COMMON_DEPEND}
  51. 	dbus? ( gnome-base/gvfs )
  52. 	gnome-base/librsvg
  53. 	|| (
  54. 		>=x11-themes/adwaita-icon-theme-2.17.1
  55. 		>=x11-themes/hicolor-icon-theme-0.10 )
  56. "
  57. DEPEND="${COMMON_DEPEND}
  58. 	app-text/docbook-xml-dtd:4.3
  59. 	dev-util/gdbus-codegen
  60. 	dev-util/glib-utils
  61. 	>=dev-util/gtk-doc-am-1.13
  62. 	>=dev-util/intltool-0.35
  63. 	dev-util/itstool
  64. 	sys-devel/gettext
  65. 	virtual/pkgconfig
  66. 	app-text/yelp-tools
  67. "
  68. # eautoreconf needs:
  69. #  app-text/yelp-tools
  71. PATCHES=(
  72. 	"${FILESDIR}"/3.30.2-internal-synctex.patch # don't automagically link to synctex from texlive-core - always use internal copy of this small parser for now; requires eautoreconf
  73. )
  75. src_prepare() {
  76. 	gnome2_src_prepare
  78. 	# Do not depend on adwaita-icon-theme, bug #326855, #391859
  79. 	# https://gitlab.freedesktop.org/xdg/default-icon-theme/issues/7
  80. 	sed -e 's/adwaita-icon-theme >= $ADWAITA_ICON_THEME_REQUIRED//g' \
  81. 		-i configure || die "sed failed"
  82. }
  84. src_configure() {
  85. 	gnome2_src_configure \
  86. 		--disable-static \
  87. 		--enable-pdf \
  88. 		--enable-comics \
  89. 		--enable-thumbnailer \
  90. 		--with-platform=gnome \
  91. 		$(use_enable dbus) \
  92. 		$(use_enable djvu) \
  93. 		$(use_enable dvi) \
  94. 		$(use_enable gstreamer multimedia) \
  95. 		$(use_enable gnome libgnome-desktop) \
  96. 		$(use_with gnome-keyring keyring) \
  97. 		$(use_enable introspection) \
  98. 		$(use_enable nautilus) \
  99. 		$(use_enable nsplugin browser-plugin) \
  100. 		$(use_enable postscript ps) \
  101. 		$(use_with spell gspell) \
  102. 		$(use_enable t1lib) \
  103. 		$(use_enable tiff) \
  104. 		$(use_enable xps) \
  105. 		BROWSER_PLUGIN_DIR="${EPREFIX}"/usr/$(get_libdir)/nsbrowser/plugins \
  106. 		--with-systemduserunitdir="$(systemd_get_userunitdir)"
  107. }