logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

fcitx-5.0.23.ebuild (2442B)

    

  1. # Copyright 2021-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit cmake xdg-utils
  8. DV="20121020"
  9. MY_PN="fcitx5"
  10. DESCRIPTION="Fcitx (Flexible Context-aware Input Tool with eXtension) input method framework"
  11. HOMEPAGE="https://fcitx-im.org/ https://github.com/fcitx/fcitx5"
  12. SRC_URI="
  13. 	https://github.com/fcitx/fcitx5/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
  14. 	https://download.fcitx-im.org/data/en_dict-${DV}.tar.gz -> fcitx-data-en_dict-${DV}.tar.gz
  15. "
  16. S="${WORKDIR}/${MY_PN}-${PV}"
  18. LICENSE="LGPL-2.1+"
  19. SLOT="5"
  20. KEYWORDS="~amd64 ~x86"
  21. IUSE="X coverage dbus doc +emoji +enchant +keyboard +libuuid +server systemd test wayland"
  22. REQUIRED_USE="coverage? ( test )"
  23. RESTRICT="!test? ( test )"
  25. DEPEND="
  26. 	X? (
  27. 		dev-libs/glib:2
  28. 		x11-libs/cairo[X]
  29. 		x11-libs/gdk-pixbuf:2
  30. 		x11-libs/libxcb[xkb]
  31. 		x11-libs/libxkbfile
  32. 		x11-libs/pango[X]
  33. 		x11-libs/xcb-util
  34. 		x11-libs/xcb-util-keysyms
  35. 		x11-libs/xcb-util-wm
  36. 		)
  37. 	dev-libs/libfmt
  38. 	emoji? (
  39. 		app-i18n/unicode-cldr
  40. 		dev-libs/expat
  41. 		)
  42. 	enchant? ( app-text/enchant:2 )
  43. 	keyboard? (
  44. 		app-text/iso-codes
  45. 		dev-libs/expat
  46. 		dev-libs/json-c
  47. 		x11-libs/libxkbcommon[X?]
  48. 		x11-misc/xkeyboard-config
  49. 		)
  50. 	libuuid? ( sys-apps/util-linux )
  51. 	sys-devel/gettext
  52. 	systemd? ( sys-apps/systemd )
  53. 	!systemd? (
  54. 		dbus? ( sys-apps/dbus )
  55. 		dev-libs/libevent
  56. 		)
  57. 	virtual/libintl
  58. 	wayland? (
  59. 		dev-libs/glib:2
  60. 		dev-libs/wayland
  61. 		dev-libs/wayland-protocols
  62. 		dev-util/wayland-scanner
  63. 		x11-libs/cairo
  64. 		x11-libs/gdk-pixbuf:2
  65. 		x11-libs/pango
  66. 		)
  67. "
  68. RDEPEND="${DEPEND}
  69. "
  70. BDEPEND="
  71. 	doc? ( app-text/doxygen )
  72. 	kde-frameworks/extra-cmake-modules
  73. 	virtual/pkgconfig
  74. "
  76. #	"${FILESDIR}/${PN}-5.0.8-fix-conflicts-with-fcitx4.diff"
  77. PATCHES=( )
  79. src_prepare() {
  80. 	cp "${DISTDIR}/fcitx-data-en_dict-${DV}.tar.gz" src/modules/spell/en_dict-${DV}.tar.gz || die
  81. 	cmake_src_prepare
  82. }
  84. src_configure() {
  85. 	local mycmakeargs=(
  86. 		-DENABLE_TEST=$(usex test)
  87. 		-DENABLE_COVERAGE=$(usex coverage)
  88. 		-DENABLE_ENCHANT=$(usex enchant)
  89. 		-DENABLE_X11=$(usex X)
  90. 		-DENABLE_WAYLAND=$(usex wayland)
  91. 		-DENABLE_DBUS=$(usex dbus)
  92. 		-DENABLE_SERVER=$(usex server)
  93. 		-DENABLE_KEYBOARD=$(usex keyboard)
  94. 		-DENABLE_EMOJI=$(usex emoji)
  95. 		-DENABLE_LIBUUID=$(usex libuuid)
  96. 		-DENABLE_DOC=$(usex doc)
  97. 		-DUSE_SYSTEMD=$(usex systemd)
  98. 	)
  99. 	cmake_src_configure
  100. }
  102. pkg_postinst() {
  103. 	xdg_icon_cache_update
  104. 	xdg_desktop_database_update
  105. }
  107. pkg_postrm() {
  108. 	xdg_icon_cache_update
  109. 	xdg_desktop_database_update
  110. }