logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://anongit.hacktivis.me/git/overlay.git/

fcitx-qt-5.0.17.ebuild (1313B)

    

  1. # Copyright 2021-2022 Gentoo Authors
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit cmake
  8. MY_PN="fcitx5-qt"
  9. DESCRIPTION="Qt library and IM module for fcitx5"
  10. HOMEPAGE="https://fcitx-im.org/ https://github.com/fcitx/fcitx5-qt"
  11. SRC_URI="https://github.com/fcitx/fcitx5-qt/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
  13. LICENSE="BSD LGPL-2.1+"
  14. SLOT="5"
  15. KEYWORDS="~amd64 ~x86"
  16. IUSE="dbus only-plugin static-plugin X"
  17. REQUIRED_USE="static-plugin? ( only-plugin )"
  19. DEPEND="
  20. 	dev-qt/qtcore:5
  21. 	dev-qt/qtgui:5
  22. 	dev-qt/qtwidgets:5
  23. 	x11-libs/libxkbcommon
  24. 	!only-plugin? ( >=app-i18n/fcitx-5.0.16:5 )
  25. 	dbus? ( dev-qt/qtdbus:5 )
  26. 	X? (
  27. 		x11-libs/libX11
  28. 		x11-libs/libxcb
  29. 	)
  30. "
  31. RDEPEND="${DEPEND}"
  32. BDEPEND="
  33. 	!only-plugin? ( sys-devel/gettext )
  34. 	kde-frameworks/extra-cmake-modules
  35. 	virtual/pkgconfig
  36. "
  38. S="${WORKDIR}/${MY_PN}-${PV}"
  40. PATCHES=(
  41. 	"${FILESDIR}/0001-CMake-Add-option-to-disable-X11-support.patch"
  42. 	"${FILESDIR}/0002-CMake-Add-option-to-disable-DBus-support.patch"
  43. )
  45. src_configure() {
  46. 	# gentoo only support qt5 officially, disable qt4 & qt6 for now
  47. 	local mycmakeargs=(
  48. 		-DENABLE_DBUS=$(usex dbus)
  49. 		-DENABLE_QT4=no
  50. 		-DENABLE_QT6=no
  51. 		-DENABLE_X11=$(usex X)
  52. 		-DBUILD_ONLY_PLUGIN=$(usex only-plugin)
  53. 		-DBUILD_STATIC_PLUGIN=$(usex static-plugin)
  54. 	)
  55. 	cmake_src_configure
  56. }