logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://anongit.hacktivis.me/git/overlay.git/

uacme-1.7.6.ebuild (1050B)

    

  1. # Copyright 2026 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit autotools
  8. DESCRIPTION="ACMEv2 client written in plain C with minimal dependencies"
  9. HOMEPAGE="https://github.com/ndilieto/uacme"
  10. SRC_URI="https://github.com/ndilieto/uacme/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
  11. LICENSE="GPL-3+"
  12. SLOT="0"
  13. KEYWORDS="~amd64"
  14. IUSE="gnutls mbedtls +openssl ualpn"
  15. REQUIRED_USE="^^ ( gnutls mbedtls openssl )"
  17. # Note: Should be able to support LibreSSL as well
  18. RDEPEND="
  19. 	virtual/pkgconfig
  20. 	>=net-misc/curl-7.38.0
  21. 	gnutls? ( >=net-libs/gnutls-3.3.30:= )
  22. 	mbedtls? ( net-libs/mbedtls:= )
  23. 	openssl? ( >=dev-libs/openssl-1.1.1:= )
  24. 	ualpn? ( dev-libs/libev )
  25. "
  26. DEPEND="${RDEPEND}"
  27. BDEPEND="app-text/asciidoc"
  29. src_prepare() {
  30. 	default
  32. 	# configure.ac requires libev/libev.m4 so generate before de-vendoring
  33. 	eautoreconf
  35. 	rm -fr libev || die
  36. }
  38. src_configure() {
  39. 	econf \
  40. 		$(use_with gnutls) \
  41. 		$(use_with mbedtls) \
  42. 		$(use_with openssl) \
  43. 		$(use_with ualpn)
  44. }