logo

blog

My website can't be that messy, right? git clone https://anongit.hacktivis.me/git/blog.git/

nginx_autoindex.xsl.in (2335B)

    

  1. <?xml version="1.0" encoding="utf-8"?>
  2. <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns="http://www.w3.org/1999/xhtml" xmlns:xi="http://www.w3.org/2001/XInclude" version="1.0" xml:space="preserve" xmlns:str="http://exslt.org/strings" exclude-result-prefixes="str">
  3. <!--
  4. 	# Do not put $uri/
  5. 	try_files $uri $uri/index.html @autoindex;
  7. 	location @autoindex {
  8. 		autoindex on;
  9. 		autoindex_format xml;
  10. 		xslt_string_param document_uri "$document_uri";
  11. 		xslt_stylesheet /srv/web/hacktivis.me/nginx_autoindex.xsl;
  12. 	}
  13. -->
  14. 	<xsl:import href="templates/en/nav.xsl"/>
  15. 	<xsl:output method="xml" encoding="UTF-8" indent="yes" omit-xml-declaration="yes"/>
  16. 	<xsl:template match="/list"><xsl:text disable-output-escaping="yes">&lt;!DOCTYPE html&gt;</xsl:text>
  17. <html xml:lang="en" lang="en">
  18. 	<head>
  19. 		<xi:include href="templates/head.xml" parse="xml" xpointer="xpointer(/xml/*)"/>
  20. 		<link rel="stylesheet" href="/css/sorttable.css?serial=2020091801"/>
  21. 		<title><xsl:value-of select="$document_uri"/> - lanodan's cyber-home</title>
  22. 	</head>
  23. 	<body>
  24. 	<xsl:call-template name="nav"/>
  25. 	<main>
  26. 		<table class="sortable">
  27. 			<thead>
  28. 				<tr><th class="sorttable_sorted">Name</th><th>Size</th><th>Last Modified</th></tr>
  29. 			</thead>
  30. 			<tbody>
  31. 				<xsl:apply-templates select="/list/directory"/>
  32. 				<xsl:apply-templates select="/list/file"/>
  33. 			</tbody>
  34. 		</table>
  35. 	</main>
  36. 	<xi:include href="templates/en/footer.shtml" parse="xml"/>
  37. 	<script src="/javascript/sorttable.js?serial=2023030902"></script>
  38. 	</body>
  39. </html></xsl:template>
  40. <!--
  41. <list>
  42. <directory mtime="2022-07-11T07:56:48Z">ci</directory>
  43. <file mtime="2020-11-11T11:55:13Z" size="113550">0001-cmake-remove-as-much-as-possible.patch</file>
  44. </list>
  45. -->
  47. 	<xsl:template match="/list/directory"><tr>
  48. 			<td><a href="./{str:encode-uri(./text(), true(), 'UTF-8')}/"><xsl:value-of select="./text()"/>/</a></td>
  49. 			<td data-value="0" data-type="int">0 B</td>
  50. 			<td><xsl:value-of select="@mtime"/></td>
  51. 		</tr></xsl:template>
  53. 	<xsl:template match="/list/file"><tr>
  54. 			<td><a href="./{str:encode-uri(./text(), true(), 'UTF-8')}"><xsl:value-of select="./text()"/></a></td>
  55. 			<td data-type="int" data-value="{@size}"><xsl:number value="@size" grouping-separator=" " grouping-size="3"/> B</td>
  56. 			<td><xsl:value-of select="@mtime"/></td>
  57. 		</tr></xsl:template>
  58. </xsl:stylesheet>