logo

blog

My website can't be that messy, right? git clone https://hacktivis.me/git/blog.git

atom.fr.xsl.in (1991B)

    

  1. <?xml version="1.0" encoding="UTF-8"?>
  2. <xsl:stylesheet version="1.0"
  3. 	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  4. 	xmlns="http://www.w3.org/1999/xhtml"
  5. 	xmlns:xhtml="http://www.w3.org/1999/xhtml"
  6. 	xmlns:xi="http://www.w3.org/2001/XInclude"
  7. 	xmlns:atom="http://www.w3.org/2005/Atom"
  8. 	xml:space="preserve"
  9. >
  10. 	<xsl:import href="templates/fr/nav.xsl" />
  11. 	<xsl:output method="xml" encoding="UTF-8" indent="yes" omit-xml-declaration="yes"/>
  12. 	<xsl:template match="/"><xsl:text disable-output-escaping='yes'>&lt;!DOCTYPE html&gt;</xsl:text>
  13. <html xml:lang="fr" lang="fr">
  14. 	<head>
  15. 		<xi:include href="templates/head.xml" parse="xml" xpointer="xpointer(/xml/*)"/>
  16. 		<title><xsl:value-of select="/atom:feed/atom:title" /></title>
  17. 	</head>
  18. 	<body>
  19. 	<xsl:call-template name="nav">
  20. 		<xsl:with-param name="feedURL" select="/atom:feed/atom:link[@rel='self']/@href"/>
  21. 	</xsl:call-template>
  22. 		<main>
  23. 			<h1><xsl:value-of select="/atom:feed/atom:title" /></h1>
  24. 			<p>Ceci est un flux atom, vous pouvez régulièrement tirer des mises à jours avec un <a href="https://fr.wikipedia.org/wiki/Agr%C3%A9gateur">lecteur de flux</a> et <a href="{/atom:feed/atom:link[@rel='self']/@href}">l'URL de ce flux</a>. Inclus ci-dessous les entrées présentes, sans leur contenu par simplification.</p>
  26. 			<xsl:apply-templates select="/atom:feed/atom:entry"/>
  27. 		</main>
  28. 	<xi:include href="templates/en/footer.shtml" parse="xml"/>
  29. 	</body>
  30. </html></xsl:template>
  32. 	<xsl:template match="atom:entry">
  33. 		<a href="{atom:id}"><h2><xsl:value-of select="atom:title"/></h2></a>
  34. 		<p class="timestamps"><xsl:apply-templates select="atom:published"/><xsl:apply-templates select="atom:updated"/></p>
  35. 		<xsl:if test="atom:content[@type='text']"><p><xsl:value-of select="atom:content"/></p></xsl:if>
  36. 	</xsl:template>
  38. <xsl:template match="atom:published">publié le <xsl:value-of select="."/></xsl:template>
  39. <xsl:template match="atom:updated">, dernière mise-à-jour le <xsl:value-of select="."/></xsl:template>
  40. </xsl:stylesheet>