logo

overlay

My own overlay for experimentations, use with caution, no support is provided git clone https://hacktivis.me/git/overlay.git

shiromino-0.2.1.ebuild (1853B)

    

  1. # Copyright 2023 Haelwenn (lanodan) Monnier <contact@hacktivis.me>
  2. # Distributed under the terms of the GNU General Public License v2
  4. EAPI=8
  6. inherit cmake
  8. DESCRIPTION="fast-paced puzzle game with roots in the arcade"
  9. HOMEPAGE="https://github.com/shiromino/shiromino"
  10. MY_PDBM_COMMIT="f16abc76419f2df31c8c3f0642bedaad99201cda"
  11. SRC_URI="
  12. 	https://github.com/shiromino/shiromino/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz
  13. 	https://github.com/nightmareci/PDBMFont/archive/${MY_PDBM_COMMIT}.tar.gz -> PDBMFont-${MY_PDBM_COMMIT}.tar.gz
  14. "
  15. PDBMFont_S="${WORKDIR}/PDBMFont-${MY_PDBM_COMMIT}/"
  17. # Main under MIT, music under CC-BY-4.0, font under Unlicense
  18. LICENSE="MIT CC-BY-4.0 Unlicense"
  19. SLOT="0"
  20. KEYWORDS="~amd64"
  21. IUSE=""
  23. BDEPEND="virtual/pkgconfig"
  25. RDEPEND="
  26. 	media-libs/libvorbis
  27. 	media-libs/libsdl2
  28. 	media-libs/sdl2-image
  29. 	media-libs/sdl2-mixer
  30. 	dev-db/sqlite:3
  31. 	dev-libs/tinyxml2:=
  32. "
  33. DEPEND="${RDEPEND}"
  35. PATCHES=( "${FILESDIR}/shiromino-0.2.1-fix_cmake_targets.patch" )
  37. src_prepare() {
  38. 	cmake_src_prepare
  40. 	rm "${PDBMFont_S}/tinyxml2.cpp" "${PDBMFont_S}/tinyxml2.h" || die
  42. 	sed -i -e 's;#include "tinyxml2.h";#include <tinyxml2.h>;' "${PDBMFont_S}/PDBMFont.hpp" || die
  43. 	# "${PDBMFont_S}/CMakeLists.txt" isn't used by Shiromino which defines it's own targets instead
  44. 	#sed -i \
  45. 	#	-e '/tinyxml2.cpp/d' \
  46. 	#	-e '/SDL2_image REQUIRED/afind_package(tinyxml2 REQUIRED)' \
  47. 	#	-e 's/SDL2_image::SDL2_image/SDL2_image::SDL2_image tinyxml2/' \
  48. 	#	"${PDBMFont_S}/CMakeLists.txt" || die
  50. 	sed -i \
  51. 		-e '/tinyxml2\./d' \
  52. 		-e '/MINIMUM_SDL2_VERSION/iset(MINIMUM_TINYXML2_VERSION 0)' \
  53. 		-e '/set(DEPENDENCIES/a		tinyxml2' \
  54. 		CMakeLists.txt || die
  55. }
  57. src_configure() {
  58. 	local mycmakeargs=(
  59. 		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
  60. 		-DFETCHCONTENT_FULLY_DISCONNECTED=ON
  61. 		-DFETCHCONTENT_SOURCE_DIR_PDBM_FONT="${PDBMFont_S}"
  62. 	)
  64. 	cmake_src_configure
  65. }